Создание нескольких программ SAS с помощью `filename` заявления

Question

Я один большой набор данных, который определяет метаданные для переменных через наборы данных в различных libnames (вытянут из sashelp.vcolumn.

Запуск через это у меня есть код вдоль линий, после чего выводит . одна большая программа - это работает отлично, однако я с тех пор узнал, мне нужно будет отвлечь имя файла, чтобы создать программу в соответствующий каталог для каждого нового имя-библ попадается:

data _null_ ; 
    set metadata end=eof ; 
    by libname memname ; 
    file sascode ; 

    if first.libname then put "proc datasets lib=" libname " nolist ;"; 
    if first.memname then put " modify "memname ";"; 
    if last.libname then put " run; 
    if eof then   put "quit ;"; 
run ; 

можно ли перенаправить оператор file в правильный каталог f или каждый first.libname?

Answer 1

Чтобы расширить ответ Reeza немного, вот как вы могли бы сделать это с помощью метаданных в dictionary.libnames. Здесь я использую dictionary.tables, но если вам нужно использовать .columns, чтобы получить (независимо от того, что вы делаете со столбцами), который должен работать так же хорошо.

libname temp 'c:\temp'; 
data class temp.class; 
set sashelp.class; 
run; 

proc sql; 
    create table metadata as 
    select T.libname, T.memname, L.path 
    from dictionary.tables T, dictionary.libnames L 
    where T.libname=L.libname 
    and T.memname='CLASS' 
    and level=0 /* this eliminates SASHELP lib which is a bit crazy */ 
    ; 
quit; 


data _null_ ; 
    set metadata end=eof; 
    by libname path memname ; 
    fn = cats(path,'\sasfile.sas'); 
    file sascode filevar=fn; 

    if first.libname then put "proc datasets lib=" libname " nolist ;"; 
    if first.memname then put " modify " memname ";"; 
    if last.libname then put " run; quit;"; 
run ; 

Answer 2

Используйте опцию FILEVAR в заявлении файла.

От SAS KB24599: http://support.sas.com/kb/24/599.html

/* Create sample data */ 

data test; 
    input color $ num; 
datalines; 
blue 1 
blue 2 
blue 3 
green 4 
green 5 
red 6 
red 7 
red 8 
; 

data _null_; 
    length fname $30.; 
    set test;  
    by color;            
    if first.color then count+1; 
    fname="C:\TEMP\file" || trim(left(put(count,8.)))||".txt"; 
    file dummy filevar=fname; 
    put color num count; 
run;