Excel VBA: #REF! Find & Replace

-1

У меня есть ряд функций, которые построены из множества наборов данных и сводных таблиц. Во время некоторых манипуляций с данными один из таблиц удаляется и воссоздается. Это нарушает несколько формул, которые зависят от этого имени таблицы.Excel VBA: #REF! Find & Replace

Я ищу, чтобы найти способ поиска и замены во всех формулах, используя VBA (помните, что все они немного разные), чтобы заменить #REF! с термином «DATASETNEW».

Пример одной такой формуле:

=IF(ISNA(VLOOKUP($A2,#REF!,4,FALSE)="12000"),"No Stock",VLOOKUP($A2,#REF!,5,FALSE))

источник

2017-02-13 Ted Joffs

Если нужно быть в VBA: Пронумеруйте Формулу всех использованныхЦеллов всех листов, либо в памяти (быстрее), либо по диапазону, затем соответствующим образом измените формулу. – PatricK

... любая идея, как я буду это делать? Я могу перебрать все ячейки с формулами и заменить всю формулу, но я не знаю, как заменить только #REF! текст? –

Найти и заменить (Ctrl + H) будет обновлять их в пределах формулы.

источник

2017-02-13 23:43:14 ClarissaHD

Да. Я действительно хотел бы сделать это программно. –

Вы можете попробовать это:

Option Explicit 

Sub ChangeFormulas() 
    Const LOOK_FOR As String = "#REF!" 
    Const REPLACE_WITH As String = "DATASETNEW" 
    Dim oWS As Worksheet, lCalcMode As Long 
    Dim aFormulas As Variant, r As Long, c As Long, bHasLookFor As Boolean 

    lCalcMode = Application.Calculation 
    Application.Calculation = xlCalculationManual 
    Debug.Print "WORKSHEET", "ROW", "COLUMN", """" & LOOK_FOR & """?", "FORMULA" 
    For Each oWS In ThisWorkbook.Worksheets 
     aFormulas = oWS.UsedRange.Formula 
     Select Case oWS.UsedRange.Cells.Count 
      Case Is > 1 
       For r = LBound(aFormulas, 1) To UBound(aFormulas, 1) 
        For c = LBound(aFormulas, 2) To UBound(aFormulas, 2) 
         bHasLookFor = (InStr(1, aFormulas(r, c), LOOK_FOR, vbTextCompare) > 0) 
         If bHasLookFor Then 
          Debug.Print oWS.Name, r, c, bHasLookFor, aFormulas(r, c) 
          oWS.UsedRange.Cells(r, c).Formula = Replace(aFormulas(r, c), LOOK_FOR, REPLACE_WITH) 
         End If 
        Next c 
       Next r 
      Case 1 
       bHasLookFor = (InStr(1, aFormulas, LOOK_FOR, vbTextCompare) > 0) 
       If bHasLookFor Then 
        Debug.Print oWS.Name, 1, 1, bHasLookFor, aFormulas 
        oWS.UsedRange.Cells(1, 1).Formula = Replace(aFormulas, LOOK_FOR, REPLACE_WITH) 
       End If 
     End Select 
    Next oWS 
    Application.Calculation = lCalcMode 
End Sub

Это будет цикл через все рабочие листы в книге, искать и при необходимости заменить эти строки. Он отображает прогресс в окне Immediate.

источник

2017-02-14 23:14:31 PatricK

Excel VBA: #REF! Find & Replace

ответ

Смежные вопросы