Как добавить функцию шага в макрос словаря

Question

Я новичок в VBA, и я использовал большую помощь на этом сайте, чтобы создать макрос, чтобы взять список чисел из одного листа (Лист 14), удалить дублировать и вставлять в другой лист (лист 2).

Я надеюсь принять это дальше, а не наклеивать клеткам один за другим, я ищу, чтобы иметь список вставленного в чередующихся рядах, т.е. D10, D12, D14 и т.д.

Я пробовал различные методы внутри этот сайт, однако безрезультатно. Я использовал разные типы функций «Step», но я изо всех сил стараюсь включить это в кодировку ниже.

Любая помощь очень ценится!

Ниже то, что у меня есть на данный момент:

Sub RUN() 

    Application.ScreenUpdating = False 
    Dim lastRow As Long 
    Dim i As Long 
    Dim dictionary As Object 
    Set dictionary = CreateObject("scripting.dictionary") 

    Sheet14.Activate 
    lastRow = Sheet14.Cells(Rows.Count, "F").End(xlUp).Row 

    On Error Resume Next 
    For i = 3 To lastRow 
    If Len(Cells(i, "F")) <> 0 Then 
     dictionary.Add Cells(i, "F").Value, 1 
    End If 
Next 

    Sheet2.Range("d10").Resize(dictionary.Count).Value = _ 
    Application.Transpose(dictionary.keys) 

    Application.ScreenUpdating = True 
    MsgBox dictionary.Count & " RUN TEMPLATES." 

End Sub 

Answer 1

Вот один подход (Кстати, я бы не назвал макро RUN):

Sub ListUniques() 

    Dim lastRow    As Long 
    Dim i      As Long 
    Dim dictionary   As Object 
    Dim vKeys 

    Application.ScreenUpdating = False 

    Set dictionary = CreateObject("scripting.dictionary") 

    With Sheet14 

    lastRow = .Cells(.Rows.Count, "F").End(xlUp).Row 

    For i = 3 To lastRow 
     If Len(.Cells(i, "F")) <> 0 Then 
      dictionary(.Cells(i, "F").Value) = 1 
     End If 
    Next 
    End With 

    vKeys = dictionary.keys 
    For i = LBound(vKeys) To UBound(vKeys) 
     Sheet2.Range("d10").Offset(2 * i).Value = vKeys(i) 
    Next i 
    Application.ScreenUpdating = True 
    MsgBox dictionary.Count & " RUN TEMPLATES." 

End Sub