Как читать .txt файл с другого сервера в классическом asp?

Question

Я читаю текстовый файл с моего сервера, как должен, с нижеследующим, но мне интересно, как я могу читать txt-файл с другого сервера? Что мне нужно сделать, чтобы заставить его работать?

Set fs=Server.CreateObject("Scripting.FileSystemObject") 
Set f=fs.OpenTextFile(Server.MapPath("files.txt"), 1) 

do while f.AtEndOfStream = false 
Response.Write(f.ReadLine) 
Response.Write("<br>") 
loop 

f.Close 
Set f=Nothing 
Set fs=Nothing 

Так что это работает, как и должно быть, но я хочу, чтобы изменить files.txt к http://www.somedomain.com/files.txt

Любой вход оценили, спасибо!

Answer 1

Клаас, попробуйте это и дайте нам знать.

<% Option Explicit %> 
<% 
Const REMOTE_FILE_URL="http://www.somedomain.com/files.txt" 

Call ShowRemoteFile 

Sub ShowRemoteFile 
    Dim objXML, strContents, arrLines 
    Dim x 
    Set objXML=Server.CreateObject("Microsoft.XMLHTTP") 

    'read text file... 
    objXML.Open "GET", REMOTE_FILE_URL, False 
    objXML.Send 
    strContents=objXML.ResponseText 
    Set objXML=Nothing 

    'split into lines and read line by line... 
    arrLines=Split(strContents, VBCrLf) 
    For x=0 To UBound(arrLines) 
     Response.Write(arrLines(x)&"<br />") 
    Next 
End Sub 
%> 

Answer 2

Используйте эту функцию для извлечения текстовых данных (взято из here):

Function GetTextFromUrl(url) 

    Dim oXMLHTTP 
    Dim strStatusTest 

    Set oXMLHTTP = CreateObject("MSXML2.ServerXMLHTTP.3.0") 

    oXMLHTTP.Open "GET", url, False 
    oXMLHTTP.Send 

    If oXMLHTTP.Status = 200 Then 

    GetTextFromUrl = oXMLHTTP.responseText 

    End If 

End Function 

Dim sResult : sResult = GetTextFromUrl("http://www.somedomain.com/files.txt")