Объединение нескольких MsgBox в один

Question

Когда мы открываем эту книгу, этот код будет просматривать диапазон и находить ячейки, содержащие текст «Ожидание RCA», и выведет MsgBox, чтобы пользователь знал, какая строка в этом столбце содержит конкретный текст , Проблема состоит в том, что если есть несколько строк, содержащих этот текст, также будут множественные всплывающие окна MsgBox.

Private Sub Auto_Open() 

Dim i As Variant 
Dim FindRange As Range 
Set FindRange = Range("AB2:AB2000") 

    For Each i In FindRange 
     If i = "RCA Pending" Then 

     MsgBox "Found 'RCA Pending' in cell" & " " & i.Address, vbExclamation, "Attention" 

     End If 
    Next i 
End Sub 

Что необходимо изменить в этом коде, так что есть только один всплывающее окно, в котором перечислены все строки, в которых были найдены «RCA Pending»?

Answer 1

Попробуйте этот код:

Private Sub Auto_Open()  

Dim i As Variant 
Dim FindRange As Range 
Dim Msg As String 
Set FindRange = Range("AB2:AB2000") 

    For Each i In FindRange 
     If i = "RCA Pending" Then 

     If Msg = "" Then 
     Msg = "Found 'RCA Pending' in cell" & " " & i.Address 
     Else 
     Msg = Msg & Chr(10) & "Found 'RCA Pending' in cell" & " " & i.Address 
     End If 

     End If 
    Next i 
    If Msg <> "" Then MsgBox Msg, vbExclamation, "Attention" 
End Sub 

Answer 2

Попробуйте это,

Sub Msgbox_It() 

    Dim sh As Worksheet 
    Dim LstRw As Long 
    Dim i As Range 
    Dim FindRange As Range 
    Dim Msg As String 

    Set sh = Sheets("Sheet1") 'name of worksheet 
    With sh 
     LstRw = .Cells(.Rows.Count, "AB").End(xlUp).Row 
     Set FindRange = .Range("AB2:AB" & LstRw) 

     For Each i In FindRange 
      If i = "RCA Pending" Then 
       Msg = Msg & i.Address & vbNewLine 
      End If 
     Next i 

     MsgBox "Found 'RCA Pending' in cell" & " " & Msg, vbExclamation, "Attention" 
    End With 
End Sub