Как объединить два файла в один?

Question

У меня есть два бинарных файла (предположим, это ZIP-файл, ранее нарезанный на 2 части). Как я могу объединить их в один файл? Точнее, добавьте второй файл к первому.

ОБНОВЛЕНИЕ: Ребята, спасибо всем, кто ответил мне, но это не совсем то, что мне нужно. В принципе, мне нужен аналог команды оболочки: "копировать/б file.000 + file.001 + file.002 file.bin"

Answer 1

Как это:

var 
    InStream, OutStream: TFileStream; 
.... 
OutStream := TFileStream.Create(OutFileName, fmCreate); 
try 
    InStream := TFileStream.Create(InFileName1, fmOpenRead); 
    try 
    OutStream.CopyFrom(InStream, InStream.Size); 
    finally 
    InStream.Free; 
    end; 
    InStream := TFileStream.Create(InFileName2, fmOpenRead); 
    try 
    OutStream.CopyFrom(InStream, InStream.Size); 
    finally 
    InStream.Free; 
    end; 
finally 
    OutStream.Free; 
end; 

или в более общем конкатенировать множественным файлы:

procedure ConcatenateFiles(const InFileNames: array of string; 
    const OutFileName: string); 
var 
    i: Integer; 
    InStream, OutStream: TFileStream; 
begin 
    OutStream := TFileStream.Create(OutFileName, fmCreate); 
    try 
    for i := 0 to high(InFileNames) do 
    begin 
     InStream := TFileStream.Create(InFileNames[i], fmOpenRead); 
     try 
     OutStream.CopyFrom(InStream, InStream.Size); 
     finally 
     InStream.Free; 
     end; 
    end; 
    finally 
    OutStream.Free; 
    end; 
end; 

вызовов это так:

ConcatenateFiles(['Part1', 'Part2'], 'Outfile.zip')