Отключить неявные транзакции

Question

Я хотел бы сделать вставку с использованием select, но я знаю, что некоторые строки могут выйти из строя (что ожидается). Есть ли способ изменить неявные транзакции SQL Server 2008 с тем, чтобы те, которые не провалились, не откат?

-- get the count of the customers to send the sms to 
SELECT @count = COUNT(*) 
FROM PreCampaignCustomer 
WHERE Processed = 0 AND CampaignID = @campaignid 
AND ErrorCount < 5 

WHILE (@count > 0) 
BEGIN 
    DECLARE @customerid INT, 
      @carrierid INT, 
      @merchantcustomerid INT, 
      @smsnumber NVARCHAR(50), 
      @couponcode NVARCHAR(20) 

    SELECT TOP 1 @customerid = pcc.CustomerID, @merchantcustomerid = pcc.MerchantCustomerID, 
    @carrierid = c.CarrierID, @smsnumber = c.SMSNumber 
    FROM PreCampaignCustomer pcc 
    INNER JOIN Customer c ON c.ID = pcc.CustomerID 
    WHERE pcc.Processed = 0 AND pcc.CampaignID = @campaignid 
    AND pcc.ErrorCount < 5 
    ORDER BY pcc.ErrorCount 

    --set the couponcode  
    IF @couponlength = -1 
    BEGIN 
     SET @couponcode = 'NOCOUPON' 
    END 
    ELSE 
    BEGIN 
     EXEC [GenerateCouponCode] 
     @length = 9, 
     @couponcode = @couponcode OUTPUT 
    END 

    BEGIN TRY 
     --use try/catch just in case the coupon code is repeated or any other error 

     --Set the coupon text 
     DECLARE @coupontext NVARCHAR(200), 
       @smsrequestxml XML 


     IF @coupontypecode = 1 --NONE 
     BEGIN 
      SET @coupontext = @merchantname + ': ' + @smsmessage + ', Use Code: ' + dbo.FormatCouponCode(@couponcode, @couponcodegrouping) + '. Reply STOP to quit' 
     END 
     ELSE 
     BEGIN 
      SET @coupontext = @merchantname + ': ' + @smsmessage + '. Reply STOP to quit' 
     END 

     EXEC GetSMSRequest @config = @smsconfig, 
        @smsType = 1, --Submit 
        @address = @smsnumber, 
        @carrierID = @carrierid, 
        @message = @coupontext, 
        @xml = @smsrequestxml OUTPUT 

     BEGIN TRAN 
      --create the CampaignCustomer record 
      INSERT INTO CampaignCustomer 
      (CampaignID, CustomerID, CouponCode, Active) 
      VALUES 
      (@campaignid, @customerid, @couponcode, 1) 

      --Add the record to the queue 
      INSERT INTO SMSQueue 
      (CarrierID, [Address], [Message], TimeToSend, RequestXML, QueueID, HTTPStatusCode, Retries) 
      VALUES 
      (@carrierid, @smsnumber, @coupontext, @timetosend, @smsrequestxml, @queueid, 0, 0) 

      --Create Outgoing SMS Log 
      INSERT INTO SMSOutgoingLog 
      (MerchantID, MerchantGroupID, MessageTypeCode, CreatedDate, Active) 
      VALUES 
      (@merchantid, @merchantgroupid, @messagetypecode, GETDATE(), 1) 

      --Update the LastSentSMSTime of the MerchantCustomer 
      UPDATE MerchantCustomer 
      SET LastSentSMS = GETDATE(), 
      ModifiedDate = GETDATE() 
      WHERE ID = @merchantcustomerid 

      UPDATE PreCampaignCustomer 
      SET Processed = 1, 
      ModifiedDate = GETDATE() 
      WHERE CustomerID = @customerid 
      AND CampaignID = @campaignid 
     COMMIT TRAN 
    END TRY 
    BEGIN CATCH 
     ROLLBACK TRAN 

     -- Set the error 
     UPDATE PreCampaignCustomer 
     SET ErrorCount = ErrorCount + 1, 
     ModifiedDate = GETDATE(), 
     ErrorMessage = ERROR_MESSAGE(), 
     ErrorNumber = ERROR_NUMBER() 
     WHERE CustomerID = @customerid 
     AND CampaignID = @campaignid 
    END CATCH 

    SELECT @count = COUNT(*) 
    FROM PreCampaignCustomer 
    WHERE Processed = 0 AND CampaignID = @campaignid 
    AND ErrorCount < 5 
END 

Answer 1

no, INSERT - это единственная команда. Транзакции контролируют, как несколько команд объединяются вместе в отдельные единицы работы, а не как строки объединяются в одну команду. У вас не может быть строк INSERT и те, которые не выполняются (некоторые проблемы ограничения) и просто игнорируются. если какие-либо строки терпят неудачу, то весь INSERT терпит неудачу.

Почему бы не попробовать изменить SELECT, чтобы исключить строки, которые не пройдут?

что-то вроде:

INSERT INTO YourTable 
     (col1, col2, col3) 
    SELECT 
     colA, colB, ColC 
     FROM YourOtherTable 
     WHERE ColA NOT IN (SELECT col1 FROM YourTable) 

Answer 2

можно управлять поведением transansactions с помощью SET XACT_ABORT OFF (ON) - more here.

Answer 3

Мышление из коробки, если вы используете SSIS для этого, вы можете отправить свои поврежденные строки по другому пути или просто выбросить их.

Answer 4

Возможно, вы, вероятно, думаете о свойстве IGNORE_DUP_KEY уникального индекса.

См. this related SO question и the official MSDN article по адресу IGNORE_DUP_KEY.

Чтобы добавить это свойство, вам нужно либо использовать ALTER INDEX, либо (если уникальное ограничение находится на первичном ключе) отбросить и воссоздать его.

Как только это на месте, любые вставки должны только отклонять недопустимые строки вместо всей партии.