Как переименовать файлы со списком имен с помощью командной строки?

Question

У меня есть папка с несколькими файлами. Все имена файлов выглядят так:

"1 зелен.doc" 
"2 будда.doc" 
"3 конфуций.doc" 

Все файлы в порядке первого номера, которые находятся в начале названий. У меня есть список имен файлов, которые содержатся в текстовом файле. Каждая строка в текстовом файле также в порядке. Итак, первая строка - это имя для первого имени файла, вторая строка - второе имя файла и так далее. Как переименовать файлы с помощью командной строки?

спасибо!

Answer 1

@echo off 
setlocal EnableDelayedExpansion 

rem The list of filenames will be read from redirected Stdin 
< filenames.txt (

    rem Process the files via FOR command 
    for %%a in (*.*) do (

     rem Read the next name from the list 
     set /P name= 

     rem Rename the file 
     ren "%%a" "!name!" 

    ) 
) 

Answer 2

Предполагая, что список имен файлов соответствует каталог списка точно, вы можете сделать это, толкая содержимое текстового файла в массив, каталог списка в другой массив, затем циклически обоих массивов с for /L, как это:

@echo off 
setlocal enabledelayedexpansion 

set "count=0" 

for /f "delims=" %%I in (textfile.txt) do (
    set "to[!count!]=%%I" 
    set /a count+=1 
) 

set "count=0" 

for %%I in (*.doc) do (
    set "from[!count!]=%%I" 
    set /a count+=1 
) 

for /L %%I in (0,1,!count!) do (
    if exist "!from[%%I]!" (
     echo ren "!from[%%I]!" "!to[%%I]!" 
    ) 
) 

Сохраните этот скрипт в файле .bat и запустите его. Удалите echo до ren, когда вы удовлетворены своим результатом, будет то, что вы намерены.