Локальная переменная, инициализированная в delphi?

Question

Во время процесса просмотра более старого программного кода возник следующий вопрос: все локальные переменные в методе инициализируются сразу после начала. Обычно локальные переменные не инициализируются. Но у нас есть процедура, в которой все переменные инициализируются равными 0. Есть ли у кого-нибудь идея, как это может произойти?

Пример:

type 
    TPrices = array[0..10, 0..5] of Integer; 

procedure DoSomething(); 
var 
    mPrices : TPrices; 
    mValue : Integer; 
begin 
    if (mPrices[0,0] = 0) then 
    MessageDlg('Zero', mtInformation, [mbOK], 0); 
    if (mValue = 0) then 
    MessageDlg('Zero Integer', mtInformation, [mbOK], 0); 
end; 

Answer 1

Это просто вниз случайно. Переменная не инициализируется. Переменная будет находиться в стеке, и если так получится, что все, что было записано последним в это место стека, равно нулю, тогда значение там будет по-прежнему равно нулю.

Локальные переменные неуправляемых типов не инициализируются. Не допускайте, чтобы совпадения, подобные приведенным выше, убеждали вас в другом.

Рассмотрим эту программу:

{$APPTYPE CONSOLE} 

type 
    TPrices = array[0..10, 0..5] of Integer; 

procedure Foo; 
var 
    mPrices: TPrices; 
begin 
    Writeln(mPrices[0,0]); 
end; 

begin 
    Foo; 
end. 

Когда я бегу на моей машине, выход:

 
1638012 

Теперь рассмотрим эту программу:

{$APPTYPE CONSOLE} 

type 
    TPrices = array[0..10, 0..5] of Integer; 

procedure Foo; 
var 
    mPrices: TPrices; 
begin 
    Writeln(mPrices[0,0]); 
    FillChar(mPrices, SizeOf(mPrices), 0); 
end; 

procedure Bar; 
var 
    mPrices: TPrices; 
begin 
    Writeln(mPrices[0,0]); 
end; 

begin 
    Foo; 
    Bar; 
end. 

На этот раз выход :

 
1638012 
0 

Бывает так, что две функции помещают свои локальные переменные в одно и то же место и тот факт, что первый вызов функции обнулял локальную переменную перед возвратом, влияет на неинициализированное значение другой локальной переменной во второй функции.

Или попробовать эту программу:

{$APPTYPE CONSOLE} 

type 
    TPrices = array[0..10, 0..5] of Integer; 

procedure Foo; 
var 
    mPrices: TPrices; 
begin 
    Writeln(mPrices[0,0]); 
    FillChar(mPrices, SizeOf(mPrices), 0); 
    mPrices[0,0] := 666; 
end; 

procedure Bar; 
var 
    mPrices: TPrices; 
begin 
    Writeln(mPrices[0,0]); 
    Writeln(mPrices[0,1]); 
end; 

begin 
    Foo; 
    Bar; 
end. 

Теперь выход:

 
1638012 
666 
0 

Как вы можете себе представить, много разных вещей может привести к содержанию этого стека пространства изменения. Так что доверься тому, что знаешь. Локальные переменные неуправляемых типов не инициализируются.