Как получить отдельные графики для каждой группы доз в SAS?

Question

Проблема в том, что я сравниваю эффективность двух уровней дозировки препарата против плацебо. Плацебо - контрольная группа, и у меня группа с низкой дозой и группа с высокой дозой. Я пытаюсь получить отдельные гистограммы и нормальные квантильные графики для каждой отдельной группы. Я не получаю никаких ошибок, но я также не нахожу ничего полезного для SAS. Кто-нибудь знает?

Вот мой код:

Data Memory; 
input dosegrp $ funct @@; datalines; 
Pla 6 Pla 5 Pla 6 Pla 8 Pla 3 Pla 4 Pla 7 Pla 4 Pla 7 Pla 6 Pla 7 Pla 8 Pla 5 Pla 6 Pla 5 Pla 5 Pla 7 Pla 8 Pla 5 Pla 9 Pla 11 Pla 4 Pla 7 
lo 8 lo 12 lo 7 lo 8 lo 5 lo 6 lo 6 lo 5 lo 3 lo 6 lo 9 lo 6 lo 11 lo 8 lo 6 lo 9 lo 11 lo 5 
hi 11 hi 7 hi 7 hi 11 hi 9 hi 9 hi 12 hi 13 hi 9 hi 13 hi 10 hi 12 hi 9 hi 15 hi 12 hi 14 hi 15 hi 12 
; 
proc sort data = Memory; by dosegrp; 
proc means mean std n data = Memory; 
by dosegrp; 
var funct; 
title1 'one-way ANOVA'; 
title2 'Homework 8 Memory function'; 
RUN; 
title 'Tests for normality'; 
proc univariate normal data = Memory; 
by dosegrp; 
var funct; 
run; 
ods graphics on; 
proc glm data = Memory plots=all; 
class dosegrp; 
model funct=dosegrp; means dosegrp/hovtest welch t dunnett('Pla'); 
contrast 'active vs placebo' dosegrp 0.5 0.5 -1; 
run; 

Answer 1

Я думаю, ваш вопрос, как получить гистограммы и квантили участков для отдельных групп для переменного.

Если это так, то у вас есть правильная процедура и вы можете использовать PROC UNIVARIATE и histogram и qqplot заявления.

title 'Tests for normality'; 

proc univariate normal data=Memory; 
    by dosegrp; 
    histogram funct; 
    qqplot funct; 
run; 

Есть еще примеры использования в документации SAS в примерах (например, см 4,28): http://support.sas.com/documentation/cdl/en/procstat/66703/HTML/default/viewer.htm#procstat_univariate_syntax30.htm