Копирование и вставка значения в пункт назначения

Question

Я копирую данные с одного листа со вчерашней информацией на другой лист с таблицей исторических данных. Первый лист на самом деле является формулой vlookup, поэтому мне нужно только вставить значение в таблицу истории. Это то, что я написал, но он говорит, что последняя строка не работает. Может ли кто-нибудь помочь?

Option Explicit 


Sub Test() 
' 
' UpdateTablesAndCharts Macro 
' 
' Keyboard Shortcut: Option+Cmd+t 
' 


Dim lngNextEmptyRow As Long 
Dim lngLastImportRow As Long 
Dim shtYstrdy As Worksheet 
Set shtYstrdy = ThisWorkbook.Worksheets("Yesterday") 

With ThisWorkbook.Worksheets("ICT Historical Crashlytics Data") 
lngNextEmptyRow = .Cells(.Rows.Count, "A").End(xlUp).Row + 1 
.Rows(lngNextEmptyRow).Insert Shift:=xlDown 
.Cells(lngNextEmptyRow, "A").Value2 = _ 
    .Cells(lngNextEmptyRow - 1, "A").Value2 + 1 
shtYstrdy.Range("AM1:AN1").Copy 
    Cells("A" & lngNextEmptyRow).PasteSpecial xlPasteValues 


End With 

End Sub 

Answer 1

1. Cells() формат Cells(Rows,Column) Вы, вероятно, хотите Range().

2. Когда вы просто вставляете значения, быстрее просто назначить их напрямую.

3. В ячейках() отсутствует . спереди, поэтому он не был присвоен надлежащему родительскому листу.

Используйте это:

Sub Test() 
' 
' UpdateTablesAndCharts Macro 
' 
' Keyboard Shortcut: Option+Cmd+t 
' 


Dim lngNextEmptyRow As Long 
Dim lngLastImportRow As Long 
Dim shtYstrdy As Worksheet 
Set shtYstrdy = ThisWorkbook.Worksheets("Yesterday") 

With ThisWorkbook.Worksheets("ICT Historical Crashlytics Data") 
    lngNextEmptyRow = .Cells(.Rows.Count, "A").End(xlUp).Row + 1 
    .Rows(lngNextEmptyRow).Insert Shift:=xlDown 
    .Cells(lngNextEmptyRow, "A").Value2 = _ 
     .Cells(lngNextEmptyRow - 1, "A").Value2 + 1 
    .Range("A" & lngNextEmptyRow).Resize(1, 2).Value = shtYstrdy.Range("AM1:AN1").Value 
End With 

End Sub