Для каждой скрытой ячейки задайте значение в ячейке в этой скрытой ячейке

Question

У меня есть таблица (A3-6), которая скрывает строки в соответствии с числом, введенным в ячейку над таблицей (A1). В столбце Row A3-6 пользователь выбирает опцию в ячейке, которая имеет список данных valadation. Теперь я хочу, чтобы каждая из скрытых ячеек устанавливала значения в скрытых ячейках по умолчанию.

Dim i As Long 
     For i = 2 To 10 
      If (Rows("2:10").Hidden = True) Then 
       'Set the default values for the cell? 
     End If 
     Next i 

Этот код скрывает строки в соответствии с номером, введенным в A1

If Target.Address = "$A$1" Then 
     Rows("3:6").Hidden = True 
     Rows("2:" & 2 + Val(Target.Value)).Hidden = False 
    End If 

Answer 1

Это может возможно дать вам несколько идей:

Sub resetHiddenRangeValue() 

    Dim rngMyRange As Range, rngVisible As Range, rngCell As Range 

    Set rngMyRange = Range("A3:A6") 
    Set rngVisible = Range("A3:A6").SpecialCells(xlCellTypeVisible) 

    For Each rngCell In rngMyRange 
     If Intersect(rngCell, rngVisible) Is Nothing Then 
      ' Is the default value rngcell.offset(0,6).value? 
      rngCell.Value = "My Default Value" 
     End If 
    Next rngCell 

End Sub 

Это можно избежать цикла, но его немного сложнее:

Sub resetHiddenRangeValueNoLooping() 

    Dim rngMyRange As Range, rngVisible As Range, rngHidden As Range, varVisible As Variant 

    Set rngMyRange = Range("A3:A6") 
    Set rngVisible = Range("A3:A6").SpecialCells(xlCellTypeVisible) 

    ' Trick: store the initial values of the visible range to a variant array 
    varVisible = rngVisible.Value 

    ' Substitute the contents of rngVisible with something random 
    rngVisible.Value = "Blah_Blah_Blah" 

    ' Use the Columndifferences method to set the hidden range 
    Set rngHidden = rngMyRange.ColumnDifferences(rngVisible(1, 1)) 

    ' Fill up the range with the default value-can also be an array or range of values 
    rngHidden.Value = "My Default Value" 

    ' restore the original values of the visible range 
    rngVisible.Value = varVisible 

End Sub