"delims = # + #" - более 1 символа в качестве разделителя

Question

Можно ли определить разделитель, который не ограничен 1 символом? Основываясь на примере названия, я хотел бы определить мой разделитель, например. '# + #'. Текстовые файлы/строки могут содержать оба символа, но есть очень мало шансов, что вы столкнетесь с этой конкретной подстрокой/текстовым комбо.

Answer 1

Нет, вы не можете использовать строку в качестве разделителя в оговорке delims=. Конечно, вы можете включить строку, но она будет обрабатываться как набор отдельных символов, которые будут использоваться как разделители, а не как строка разделителя.

Если вам действительно нужно разбить на строки, самый быстрый подход мог бы заменить разделитель строки персонажем, не включенных в данные и использовать этот символ в качестве разделителя

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for /f "delims=" %%a in ("this is a +test!! #+# of string #splitting#") do (
     set "buffer=%%a" 
     setlocal enabledelayedexpansion 
     (for /f "tokens=1,2 delims=¬" %%b in ("!buffer:#+#=¬!") do (
      endlocal 
      echo full line : [%%a] 
      echo first token : [%%b] 
      echo second token : [%%c] 
     )) || if "!!"=="" endlocal 
    ) 

Примечание : setlocal enabledelayedexpansion необходим, чтобы читать переменную, измененную внутри цикла for, получая данные (здесь имитируется непосредственно, включая строку). Затем внутри цикла for, который токенизирует прочитанную строку, замедленное расширение отключается, чтобы избежать проблем с символами ! (если активное приложение с задержкой активно, они будут потребляться синтаксическим анализатором). Это является причиной для endlocal внутри цикла.

Как мы делаем замену строки и можно закончить со строкой, состоящей только из разделителей, возможно, что положение внутреннего fordo не будет выполнено, поэтому окончательный if включен для того, чтобы enabledelayedexpansion отменен.

Answer 2

Недавно я обнаружил интересный трюк, который позволяет использовать многосимвольную строку как разделитель, чтобы разделить большую строку очень простым способом; метод не использует команду for, но выполняет разделение только в одной строке! Вот оно:

@echo off 

set "str=this is a +test!! #+# of string #splitting#" 

set "first=%str:#+#=" & set "last=%" 

echo full line : [%str%] 
echo first token : [%first%] 
echo last token : [%last%] 

Этот метод также позволяет разделить большой строку на несколько частей и сохранить все они в массиве. Дополнительная информация: dos batch iterate through a delimited string