Заполняем ячейки с именами файлов в папке, Excel

Question

Я использую Excel 2010

Я хотел бы, чтобы вставить имя файла списка файлов жгутов определенную папку в ячейку Excel.

I.e. если путь к файлу: C: \ Users \ ИМЯ \ Documents \ путь_к_папка

и в путь_к_папке У меня есть несколько файлов определенного типа (File001.DAT ... File00N.DAT)

Как я могу заполнять все ячейки в пределах определенного столбца (и начиная с определенной строки) с именами файлов *. DAT?

Заранее спасибо.

Обновление: Я использовал командную строку для ввода имен файлов в текстовый файл. В командной строке я переходите к каталогу в вопрос:

CD/Каталог/О/Напильники

, а затем я написал файлы в текстовый файл следующим образом:

реж/б * .png > FIles.txt

флаг/b дает мне только имена. Затем я скопировал все имена и вложил их в Excel. Это не так здорово, как решение Брюса Уэйна, но на данный момент это то, что мне нужно.

Answer 1

Просто извлеките выход из команды DIR через стандартный выходной поток. Гораздо быстрее, чем Dir$() и нет необходимости в каких-либо петель !:

Sub Foo() 

Dim strFolderName As String 
Dim strFileType  As String 
Dim pasteRange  As Range 
Dim returnVals  As Variant 

'// set parameters, change as required 
strFolderName = "C:\Users\NAME\Documents\FolderPath\" 
strFileType = "*.DAT" 
Set pasteRange = Range("C5") 

'// retrieve output of DIR command from CMD.exe 
returnVals = Filter(Split(CreateObject("WScript.Shell").Exec("CMD /C DIR """ & strFolderName & _ 
       strFileType & """ /B /A:-D").StdOut.ReadAll, vbCrLf), ".") 

'// Display results in chosen column 
pasteRange.Resize(UBound(returnVals) + 1, 1).value = WorksheetFunction.Transpose(returnVals) 

End Sub 

Answer 2

быстрый и простой способ, чтобы использовать цикл, который просто проверяет расширение каждого файла в каталоге:

Sub t() 
Dim MyObj As Object, MySource As Object, file As Variant 
Dim i& 

file = Dir("C:\Users\me\Desktop\") 
i = 1 
While (file <> "") 
    Debug.Print Right(file, 3) 
     If Right(file, 3) = "dat" Then 
     Cells(i, 1).Value = "found " & file 
     i = i + 1 
     End If 
    file = Dir 
    Wend 
End Sub 

Просто отрегулируйте Cells(i,1) по мере необходимости.

Answer 3

Другой способ - хотя функция EnumerateFiles в основном такая же, как BruceWaynes.

Sub PopulateSheet() 

    Dim lRow As Long 
    Dim colFiles As Collection 
    Dim vFile As Variant 

    With ThisWorkbook.Worksheets("Sheet1") 

     'This will find the last row in column A, but 
     'can use a static number or any other method to return a row number. 
     lRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1 
     Set colFiles = New Collection 

     'Remember to put the final \ in the file path. 
     EnumerateFiles "C:\Users\NAME\Documents\FolderPath\", _ 
      "*.DAT", colFiles 

     For Each vFile In colFiles 
      .Cells(lRow, 1) = Mid(vFile, InStrRev(vFile, "\") + 1) 
      lRow = lRow + 1 
     Next vFile 

    End With 

End Sub 

'//Places all file names with FileSpec extension into a collection. 
Sub EnumerateFiles(ByVal sDirectory As String, _ 
    ByVal sFileSpec As String, _ 
    ByRef cCollection As Collection) 

    Dim sTemp As String 

    sTemp = Dir$(sDirectory & sFileSpec) 
    Do While Len(sTemp) > 0 
     cCollection.Add sDirectory & sTemp 
     sTemp = Dir$ 
    Loop 
End Sub