Код VBA работает только для некоторых диаграмм

Question

Мой код VBA для обновления диапазона вторичных осей на всех графиках рабочего листа работает только для некоторых графиков. После запуска макроса отображается сообщение «Метод« Оси »объекта« _Chart »failed», при этом обновляются только некоторые из графиков на этом листе. В чем проблема?

Sub Macro1() 

Dim objChart As ChartObject, lower As Double, upper As Double 

lower = Application.InputBox(prompt:="Enter lower bound", Type:=1) 
upper = Application.InputBox(prompt:="Enter upper bound", Type:=1) 

For Each objChart In Sheets("Summary").ChartObjects 
    With objChart.Chart.Axes(xlValue, xlSecondary) 
     .MinimumScale = lower 
     .MaximumScale = upper 
    End With 
Next objChart 

End Sub 

Answer 1

Если ChartObject не имеет вторичную ось, доступ к ней вызовет ошибку. Я не мог понять способ воспроизвести вашу точную ошибку, но, как я уже говорил в a comment, извлекая процедуру и обработки ошибок времени выполнения должны, по крайней мере, поможет диагностировать проблему и сделать итерацию цикла все графики:

Public Sub UpdateSummarySheetChartAxes() 

    Dim lower As Double 
    lower = Application.InputBox(prompt:="Enter lower bound", Type:=1) 

    Dim upper As Double   
    upper = Application.InputBox(prompt:="Enter upper bound", Type:=1) 

    Dim objChart As ChartObject 
    For Each objChart In Sheets("Summary").ChartObjects 
     UpdateChartAxes objChart, lower, upper 
    Next objChart 

End Sub 

Private Sub UpdateChartAxes(ByVal objChart As ChartObject, ByVal lower As Double, ByVal upper As Double) 
    On Error GoTo CleanFail 
    With objChart.Chart.Axes(xlValue, xlSecondary) 
     .MinimumScale = lower 
     .MaximumScale = upper 
    End With 
CleanExit: 
    Exit Sub 
CleanFail: 
    Debug.Print "Failed updating axes for chart '" & objChart.Name & "'. Message: " & Err.Description 
    Resume CleanExit 
End Sub