Как объединить столбцы с разных листов без дубликатов?

Question

Как слить два столбца данных из двух разных листов в один столбец на третьем листе без дубликатов?

Например:

Лист 1

ID 
1 
2 
3 

и Лист 2

ID 
1 
6 
7 
3 

стали Лист 3

1 
2 
3 
6 
7 

Answer 1

Это можно делать с помощью Exten Sion обычной формулы для перечисления уникальных значений, которые были бы

=INDEX(Sheet1!$A$2:$A$4, MATCH(0, COUNTIF($a$1:a1, Sheet1!$A$2:$A$4), 0)) 

для первого списка

и

=INDEX(Sheet2!$A$2:$A$5, MATCH(0, COUNTIF($a$1:a1, Sheet2!$A$2:$A$5), 0)) 

для второго списка

В псевдокоде

If at end of first list 
    If at end of second list 
     Show nothing 
    Else 
     Show next item from second list 
Else 
    If at end of second list 
     Show next item from first list 
    ELse 
     Show smaller of (next item from first list, next item from second list) 

Таким образом, объединенная формула будет

=IF(ISERROR(INDEX(Sheet1!$A$2:$A$4, MATCH(0, COUNTIF($A$1:A1, Sheet1!$A$2:$A$4), 0))), 
    IF(ISERROR(INDEX(Sheet2!$A$2:$A$5, MATCH(0, COUNTIF($A$1:A1, Sheet2!$A$2:$A$5), 0))), 
    "", 
    INDEX(Sheet2!$A$2:$A$5, MATCH(0, COUNTIF($A$1:A1, Sheet2!$A$2:$A$5), 0))), 
    IF(ISERROR(INDEX(Sheet2!$A$2:$A$5, MATCH(0, COUNTIF($A$1:A1, Sheet2!$A$2:$A$5), 0))), 
    INDEX(Sheet1!$A$2:$A$4, MATCH(0, COUNTIF($A$1:A1, Sheet1!$A$2:$A$4), 0)), 
    MIN(INDEX(Sheet1!$A$2:$A$4, MATCH(0, COUNTIF($A$1:A1, Sheet1!$A$2:$A$4), 0)), 
    INDEX(Sheet2!$A$2:$A$5, MATCH(0, COUNTIF($A$1:A1, Sheet2!$A$2:$A$5), 0))) 
)) 

начиная с Sheet3! A2.

Все это формулы массива.

Эта версия работает только для чисел.

версия, которая работает для чисел и текста: -

=IF(ISERROR(INDEX(Sheet1!$A$2:$A$4,MATCH(0,COUNTIF($A$1:A1,Sheet1! $A$2:$A$4),0))), 
    IF(ISERROR(INDEX(Sheet2!$A$2:$A$5,MATCH(0,COUNTIF($A$1:A1,Sheet2! $A$2:$A$5),0))), 
    "", 
    INDEX(Sheet2!$A$2:$A$5,MATCH(0,COUNTIF($A$1:A1,Sheet2!$A$2:$A$5),0))), 
    IF(ISERROR(INDEX(Sheet2!$A$2:$A$5,MATCH(0,COUNTIF($A$1:A1,Sheet2!$A$2:$A$5),0))), 
    INDEX(Sheet1!$A$2:$A$4,MATCH(0,COUNTIF($A$1:A1,Sheet1!$A$2:$A$4),0)), 
    IF(INDEX(Sheet1!$A$2:$A$4,MATCH(0,COUNTIF($A$1:A1,Sheet1!$A$2:$A$4),0)) 
    <INDEX(Sheet2!$A$2:$A$5,MATCH(0,COUNTIF($A$1:A1,Sheet2!$A$2:$A$5),0)), 
    INDEX(Sheet1!$A$2:$A$4,MATCH(0,COUNTIF($A$1:A1,Sheet1!$A$2:$A$4),0)), 
    INDEX (Sheet2!$A$2:$A$5,MATCH(0,COUNTIF($A$1:A1,Sheet2!$A$2:$A$5),0))) 
)) 

й не сортирует

й Не пропускает пробела

✓ ли сохранить порядок, если списки уже в порядке возрастания заказ.