Параллельная обработка в SAS, ждет бесплатных сеансов

Question

Say я 2 сессии подписанная:

signon slave1; 
signon slave2; 

Скажем, у меня есть 10 заданий, выполняемых

%execute_job(parameter= 1); 
%execute_job(parameter= 2); 
%execute_job(parameter= 3); 
. 
. 
. 
%execute_job(parameter= 10); 

Что мне нужно сделать, чтобы добавить в% execute_job так что он будет продолжать ждать бесплатного сеанса и отправить задание на первый свободный сеанс, который он найдет?

Я попробовал вещи в макваре безрезультатно.

Answer 1

Хорошо, я думаю, что есть кое-что:

options sascmd="!sascmd"; 


%macro job(value); 

    %local slave_id; 

    %let slave_id = 1; 

    %do %while(&&slave&slave_id.); 
     %put Slave&slave_id. is busy and cannot be assigned job; 

     %if &slave_id. < 2 %then 
      %let slave_id = %eval(&slave_id. + 1); 
     %else 
      %let slave_id = 1; 
    %end; 

    %put Slave&slave_id. is free and is assigned job; 

    %syslput _user_ /remote= slave&slave_id.; 

    rsubmit slave&slave_id. macvar=slave&slave_id. wait=no; 


     data _null_; 

      file print; 
      put "&value. by &slave_id.!"; 

     run; 

    endrsubmit; 

%mend job; 

signon slave1 macvar=slave1; 
signon slave2 macvar=slave2; 

%job(6); 

%job(7); 

%job(8); 

signoff slave1; 
signoff slave2; 

Answer 2

Рассмотрим это: Я использую cmacvar опцию входа в систему, чтобы выделить локальный вар макрос для статуса удаленного сеанса. В syslput я создал удаленный my_id макрос var на обоих подчиненных, чтобы они знали «кто они».

Тогда у меня есть% job macro получение ID slave для запуска некоторого кода. Для реального мира также должен быть некоторый параметр работы. Здесь я просто имитирую более короткое job1 и более длинное job2.

В% run_jobs Я делаю несколько циклов, чтобы попытаться запустить подчиненные несколько раз. Главное, что вы делаете в WAITFOR _ANY_.

signon slave1 sascmd="!sascmd" cmacvar=slave1; 
signon slave2 sascmd="!sascmd" cmacvar=slave2; 

%syslput my_id=1 /remote=slave1; 
%syslput my_id=2 /remote=slave2; 

rsubmit slave1; 
options nomprint nosource nonotes; 
endrsubmit; 
rsubmit slave2; 
options nomprint nosource nonotes; 
endrsubmit; 
/* 
my_id is remote 
slave_id is local 
*/; 
%macro job(slave_id); 
rsubmit slave&slave_id. wait=no; 
    data _null_; 
     %if &slave_id eq 2 %then %do; 
      x = sleep(2); 
     %end; 
     x = sleep(4); 
     s = put(DATETIME(), DATETIME.) || " at &my_id.!"; 
     putlog s; 
    run; 
endrsubmit; 
%mend; 


%macro run_jobs; 
    %do i=1 %to 4; 
     %if &slave1 eq 0 %then %do; 
      %put Slave1 starting; 
      %job(1) 
     %end; 
     %else %put Slave1 working; 
     %if &slave2 eq 0 %then %do; 
      %put Slave2 starting; 
      %job(2) 
      %put Slave2: &slave2; 
     %end; 
     %else %put Slave2 working; 
     WAITFOR _any_ slave1 slave2; 
     *LISTTASK _ALL_ ; 
     %put at end of loop &i:; 
     %put Slave1: &slave1; 
     %put Slave2: &slave2; 
    %end; 
%mend; 


options nomprint nosource nonotes; 
%run_jobs 

signoff slave1; 
signoff slave2;