Учитывая последовательность путей XML, создавать структуру XML дерева

Question

Я хочу, чтобы решить проблему - задана произвольная последовательность XML-пути, я хочу, чтобы создать структуру XML-дерева:

например учитывая эту последовательность:

"/person/name" "/person/address" "/person/age" "/person/parent/name" 

генерации:

<person> 
<name></name> 
<address></address> 
<parent> 
<name></name> 
</parent> 
</person> 

Кто-нибудь знает хороший пример того, как сделать это в XQuery и/или XSLT?

Thanks

Answer 1

Это проблема рекурсии. Вы хотите обрабатывать все XPaths сразу, но потреблять их шаг за шагом. На каждом шаге идентифицируйте отдельные элементы, которые необходимо создать, создать их, а затем внутри каждого, рекурсивно вызвать ту же функцию на хвостах всех путей, которые проходят через этот новый элемент.

declare function local:generate($paths) { 
    if(fn:empty($paths)) then() else 

    let $heads := $paths ! fn:subsequence(fn:tokenize(.,'/'),1,1) 
    let $tails := $paths ! fn:string-join(fn:subsequence(fn:tokenize(.,'/'),2),'/') 

    for $element in fn:distinct-values($heads) 
    return 
     if($element='') then local:generate($tails) 
     else element { xs:QName($element) } { 
      let $nextPaths := for $tail at $n in $tails where fn:starts-with($paths[$n],$element||'/') return $tail 
      return local:generate($nextPaths) 
     } 
}; 

local:generate(("/person/name", "/person/address", "/person/age", "/person/parent/name"))