Excel массив VBA из данных

Question

Мне нужно создать массив из списка данных в excel. Данные будут иметь разную длину, поэтому мне придется найти конец, а затем создать массив. Затем мне нужно пройти через массив и использовать каждое значение. Я раньше не использовал VBA, поэтому ничего полезного. Это то, что я получил до сих пор:

Sub Calc() 
Dim endCell As String  
endCell = Range("B13").End(xlDown).Row  
endCell = "B13:B" + endCell  
Dim nums As Variant 

nums = Range(endCell) 

End Sub 

Answer 1

использовать функцию транспонирования:

nums = Application.WorksheetFunction.Transpose(Range(endCell).value) 

Answer 2

Вам не придется этого делать. Просто сделайте это:

Dim varValues() as Variant 

' ... 

varValues = Range(endCell).Value 

Для объекта диапазона, который содержит более одной ячейки, свойство value возвращает массив значений.

Если вы не знаете, есть ли диапазон более одной ячейки, но вы хотите иметь массив значений независимо, вы могли бы написать функцию для достижения этого (спасибо brettdj за вдохновение):

Function GetValue(rng As Range) As Variant() 
    Dim varResult() As Variant 

    If rng.Cells.Count = 1 Then 
     ReDim varResult(0 To 0) 'I prefer to be explicit about the base 
     varResult(0) = rng.Value 
    Else 
     varResult = rng.Value 
    End If 

    GetValue = varResult 
End Function 

Answer 3

Начиная с вашего кода, вы могли бы перебираем массив следующим образом:

Sub Calc() 
    Dim endCell As String 

    endCell = Range("B13").End(xlDown).Row 
    endCell = "B13:B" & endCell 

    Dim nums As Variant 
    Dim i As Long 

    nums = Range(endCell) 

    For i = LBound(nums,1) To UBound(nums,1) 
     'do something with nums(i,1) 
    Next i 
End Sub 

Answer 4

Я не уверен, что это лучше или чище.

Sub Calc() 
Dim endCell As String 

endCell = Range("B13").End(xlDown).Row 
endCell = "B13:B" & endCell 
Range(endCell).select 

For each c in selection 
    use any attribute of the cells one at a time like, c.value c.formula..... 
Next c 
End Sub