if/then formula over many rows

Question

Я пытаюсь создать код (простой для некоторых), но я неопытный и ценю помощь.

код смотреть на клетку ("J1") и делать в if/then для результата в («K1»), но я хочу, чтобы это дублированный смотреть на огневом J2 to J10 клетки, чтобы дать результат в диапазоне K2 to K10 клеток также. Приведенный ниже код работает для одной строки формулы:

Sub Check() 
     Dim DDDD As Date, result As String 
     DDDD = Range("j1").Value 
     If DDDD >= Date Then 
      result = "Future" 
     Else 
      result = "Now" 
     End If 
     Range("k1").Value = result 
    End Sub 

Answer 1

Вы можете использовать For Each цикл и метод Offset, как это:

Sub Check() 
    Dim DDDD As Date, result As String 
    Dim cell as Range 

    For Each cell in Range("J1:J10") 
     DDDD = cell.Value 
     If DDDD >= Date Then 
      result = "Future" 
     Else 
      result = "Now" 
     End If 
     ' Change value at the right side of the cell 
     cell.Offset(0,1).Value = result 
    Next cell 
End Sub 

Но с помощью VBA для этого действительно слишком много. Вы можете просто положить эту формулу в K1:

=IF(J1 >= TODAY(), "Future", "Now") 

... и затем копировать/перетащить эту формулу вниз на другие клетки ниже нее.

Answer 2

Вот фрагмент кода, который перебирает колонке J, а результат будет помещен в колонке K.

Sub Check() 

Dim DDDD As Date 
Dim result As String 
Dim row, NumofRows As Integer 

' use NumfofRows as a Dynamic value to decide how many rows of data you want to look at column J 
NumofRows = 10 

For row = 1 To NumofRows 
    If Cells(row, 10) >= Date Then 
     result = "Future" 
    Else 
     result = "Now" 
    End If 
    Cells(row, 11).Value = result 
Next 

End Sub 

Answer 3

В будущем взгляните на rules of etiquette, чтобы ваши вопросы были интересными и заманчивыми для ответа. По вашему вопросу, будет более эффективным иметь дело с диапазонами, а не с отдельными ячейками с датами в них. Цикл For Each...Next может проходить через каждую ячейку диапазона. Затем петля If...Then...Else...End If может принимать решение при различных условиях. Метод Offset(0, 1) может использоваться внутри цикла If...Then для размещения результатов в столбце справа. Следующий код делает то, что вы, кажется, задаются вопросом:

Sub Check() 
' Declare your variables 
    Dim MyDates As Range 
    Dim result As String 

' First, grab all the values in the J2:JX column, where 
' X can be any number of dates you choose. Note that 
' you must "Set" Object variables, but you must "Dim" 
' other types of variables. 
    Set MyDates = Range(Range("J2"), Range("J2").End(xlDown)) 

' Loop through every cell in the dates column and give the 
' offset column (column K) a string value if the condition 
' is met. 
    Dim Cell As Range 
    For Each Cell In MyDates 
     If Cell >= Date Then 
      result = "Future" 
      Cell.Offset(0, 1).Value = result 
     Else 
      result = "Now (or past)" 
      Cell.Offset(0, 1).Value = result 
     End If 
    Next Cell 
End Sub 

метод End(xlDown) эмулирует выбора ячейки и нажав Ctrl + стрелка вниз. Также обратите внимание, что этот код вообще не обрабатывает ошибки. Например, если вы случайно введите дату как текст, процедура приведет к неправильному результату. Кроме того, в зависимости от времени ввода данных вы можете получить путаные результаты. Я приложил изображение результатов в Excel здесь: