IdHttpServer форма заголовок не обновляя

Question

Я знаю, что я отправил подобный вопрос раньше, но я не смог получить его работу у меня есть этот простой код:

procedure TfrmMain.srvrConnect(AContext: TIdContext); //idhttpserver on connect event 
var 
    S,C : String; 
begin 
repeat 
    s := s + AContext.Connection.Socket.ReadChar; 
until AContext.Connection.Socket.InputBufferIsEmpty = True; 
frmMain.caption := S; 
Memo1.Lines.Add(S); 
end; 

Строки отображаются нормально в памятке, но заголовок Безразлично Не обновляйтесь

Answer 1

TIdHTTPServer - многопоточный компонент. TIdContext работает в своем рабочем потоке. Вы не можете безопасно обновить форму Caption (или сделать что-либо еще с пользовательским интерфейсом) из-за пределов основного потока. Вам необходимо синхронизировать с основным потоком, например, с классом TIdSync или TIdNotify.

На боковой ноте вызов ReadChar() в цикле очень неэффективен, не говоря уже о склонности к ошибкам, если вы используете Delphi 2009+, поскольку он не может вернуть данные для суррогатных пар.

Используйте вместо этого что-то большее;

type 
    TDataNotify = class(TIdNotify) 
    protected 
    Data: String; 
    procedure DoNotify; override; 
    public 
    constructor Create(const S: String); 
    class procedure DataAvailable(const S: String); 
    end; 

constructor TDataNotify.Create(const S: String); 
begin 
    inherited Create; 
    Data := S; 
end; 

procedure TDataNotify.DoNotify; 
begin 
    frmMain.Caption := Data; 
    frmMain.Memo1.Lines.Add(Data); 
end; 

class procedure TDataNotify.DataAvailable(const S: String); 
begin 
    Create(S).Notify; 
end; 

procedure TfrmMain.srvrConnect(AContext: TIdContext); //idhttpserver on connect event 
var 
    S: String; 
begin 
    AContext.Connection.IOHandler.CheckForDataOnSource(IdTimeoutDefault); 
    if not AContext.Connection.IOHandler.InputBufferIsEmpty then 
    begin 
    S := AContext.Connection.IOHandler.InputBufferAsString; 
    TDataNotify.DataAvailable(S); 
    end; 
end; 

Answer 2

Во-первых, убедитесь, что вы пишете нужную переменную. Вы уверены, что frmMain - это форма, которую вы хотите изменить подписи?

Кроме того, вы можете попробовать:

procedure TfrmMain.srvrConnect(AContext: TIdContext); //idhttpserver on connect event 
var 
    S,C : String; 
begin 
repeat 
    s := s + AContext.Connection.Socket.ReadChar; 
until AContext.Connection.Socket.InputBufferIsEmpty = True; 
oCaption := S; 
TThread.Synchronize(nil, Self.ChangeCaption); 
end; 

procedure TfrmMain.ChangeCaption; 
begin 
Self.Caption := oCaption; 
Memo1.Lines.Add(oCaption); 
end; 

И, наконец, убедитесь, что первая линия на S не пустая строка, потому что подпись формы не будет показывать строки, которые содержат строки.