Gnuplot; итерация по файлам в каталоге для печати png

Question

В каталоге l250 У меня есть несколько файлов. Каждый из них начинает с «l2_» часть после того, как это числовое значение. Я хочу, чтобы иметь возможность строить то, что находится в файле last.sh для примерно 300 файлов. Я хочу знать, каким образом я могу перебирать файл, и это будет 1 доллар, а второе значение - 2 доллара.

Я думал, что, поскольку файлы находятся в текущем каталоге, я могу использовать для. Но тогда я читаю об awk и csv, и я не знаю, что делать. Я хотел бы получить представление о том, какой будет лучший способ перебора большого количества файлов rater, а затем поместить его в main.sh и запустить это.

main.sh

sh last.sh l2_4 1 
sh last.sh l2_5 2 
sh last.sh l2_6 3 
sh last.sh l2_7 4 
. 
. 
. 

last.sh

gnuplot << EOF 
set terminal png 
set output "finished/$1.png" 
set xlabel "Angs" 
set ylabel "Angs" 
set title "$1 | $2 fs " 
set zrange [0: 0.00001] 
set pm3d map 
splot "$1" 
EOF 

я запустить в командной строке:

$sh main.sh 

Answer 1

Сначала вы создаете список, содержащий имена всех файлов с

list = system('ls l2_*') 

, которые затем можно перебрать с do for ... (требуется Gnuplot 4.6):

set terminal pngcairo 
set xlabel "Angs" 
set ylabel "Angs" 
set zrange [0: 0.00001] 
set pm3d map 

list = system('ls l2_*') 
i = 1 

do for [file in list] { 
    set output sprintf('finished/%s.png', file) 
    set title sprintf("%s | %d fs", file, i) 
    splot file 
    i = i + 1 
}