Определить, существует ли поле имен в наборе записей

Question

Можно ли проверить, находится ли именованное поле в пределах набора записей?

EG ID, field1, field2, field3 выбраны. Возможно ли, чтобы VBScript обнаружил, выбрано ли поле2. Я также надеюсь, что это возможно без цикла

Пожалуйста, предположите, что я не знаю и не могу увидеть фактический SELECT. Мне нужно обнаружить это после выполнения запроса.

Это как его сделать с помощью цикла, я также надеюсь, что это возможно без зацикливания:

dim rs,field,foundField 
sql = "SELECT * from table;" 
set rs = conn.execute(sql) 
For Each field in rs.Fields 
    if field.Name = "someFieldName" then 
     foundField = true 
    exit for 
    else 
     foundField = false 
    end if 
next 

TYIA

Answer 1

Я думаю, что вам нужен цикл. Найдено на MSDN (выделено мной):

Большинство встроенных объектов ASP предоставляют коллекции. Коллекции - это структуры данных, подобные массивам, которые хранят строки, числа, объекты и другие значения. В отличие от массивов, коллекции расширяются и автоматически сжимаются , поскольку элементы извлекаются или сохраняются. Позиция элемента также будет перемещаться по мере изменения коллекции. Вы можете получить доступ к элементу в коллекции по его уникальному строковому ключу, по его индексу (положению) в коллекции или путем итерации по всем предметам в коллекции .

В любом случае, вы могли бы попробовать это (непроверенные):

dim rs,field,foundField 
sql = "SELECT * from table;" 
set rs = conn.execute(sql) 
if rs.Fields("someFieldName") then 
    ' ... if this doesn't crash, it may return 
    ' false negatives for columns containing null or 0 
end if 

Answer 2

Я использую ту же функцию (в VB6) к предложенному bfavaretto ... Мне интересно, почему OP говорит, что он не работает?

Public Function FieldExists(ByVal rs As Recordset, ByVal fieldName As String) As Boolean 

    On Error GoTo merr 

    FieldExists = rs.Fields(fieldName).name <> "" 
    Exit Function 

merr: 
    FieldExists = False 

End Function 

Эта функция работает для меня ... и она не возвращает ложных негативов, насколько я знаю. Кроме того, он работает быстрее, чем выполнение цикла для полей, включенных в коллекцию; для полей, которые на самом деле отсутствуют, времена выполнения обоих методов кажутся эквивалентными.

---

EDIT

Для VBScript, выше функция будет выглядеть следующим образом:

Function FieldExists(ByVal rs, ByVal fieldName) 

    On Error Resume Next 
    FieldExists = rs.Fields(fieldName).name <> "" 
    If Err <> 0 Then FieldExists = False 
    Err.Clear 

End Function 

И код отвечал в вопрос будет выглядеть так:

dim rs,field,foundField 
sql = "SELECT * from table;" 
set rs = conn.execute(sql) 
foundField = FieldExists(rs, "someFieldName")