установить значения по именам файлов в каталоге

Question

Привет Я хочу установить значение InFile для всех текстовых файлов в каталоге, что означает, что я хочу, чтобы пакетный файл загружался и выполнял команду для всех текстовых файлов в каталоге по одному один.

Обычно я просто копирую команду сколько раз файлов, то я заменяю Infile на каждое имя файла. По этому коду я получаю имена файлов, а затем я их заменяю.

cd /d "dir" 
dir /a /b /-p /o:gen >names.txt 

и вот пример команды.

@Echo OFF 
REM Set These Variables 
SET "InFile=123.txt" 
SET "OutFile=NowLoad.txt" 
SET "Replace=KK" 
SET "ReplaceWith=JJ" 

REM Get Total Lines Number [including empty lines] 
FOR /F %%A IN ('TYPE "%InFile%"^|find /v /c ""') DO SET "Till=%%A" 

REM Create The OutFile with changes 
SETLOCAL EnableDelayedExpansion 
<"!InFile!" (
    FOR /L %%a IN (1 1 0) DO SET /p "=" 
    FOR /L %%A IN (1 1 %Till%) DO (
    SET "line=" 
    SET /P "line=" 
    IF "!line!x" == "x" (Echo. 
    ) ELSE (Echo !line:%Replace%=%ReplaceWith%!) 
) 
)>>"%OutFile%" 

ENDLOCAL 

Answer 1

Другой способ ...

Ваш скрипт DOIT.bat.

Изменение DOIT.bat для использования параметра командной строки для имени файла, который вы хотите обработать.

@Echo OFF 
REM Set These Variables 
SET "InFile=%~1" 
SET "OutFile=NowLoad.txt" 
... 

Создайте еще один файл с именем CALLIT.bat

@ECHO OFF 
FOR /F "usebackq tokens=*" %%f IN (`dir /b *.txt`) DO (
    CALL DOIT.bat "%%~f" 
) 

Запуск CALLIT.bat будет обрабатывать каждый файл .txt в каталоге.

Answer 2

нет необходимости рассчитывать строки, просто обрабатывать каждую строку:

setlocal enabledelayedexpansion 
for %%f in (*.txt) do (
    (for /f "delims=" %%A in (%%f) do (
     set line=%%A 
     set line=!line:%Replace%=%ReplaceWith%! 
     echo(!line! 
    ) 
)>%%~nf.out 
) 

Замечание: при ( после echo обрабатывает пустые строки (пустая строка пишется не «эхо выключено», если !line! пуст)

отредактировал для обработки всех файлов .txt в папке. Поскольку фиксированный% oufile% затирает же выходной_файл с каждым переработанного INFILE, я изменил его на новый Extension: <SameNameAsInputFile>.out