Пакетное программирование для переименования файлов

Question

Я бы хотел переименовать файлы с помощью пакетного скрипта.

Файлы в настоящее время названы так:

pkg_mon_doc_kpps_01.html 
pkg_mon_doc_kpps_10.html 
pkg_mon_doc_kpps_02.html 

И я хотел бы изменить их:

data_1.xls 
data_2.xls 
data_3.xls 

Я сделал пакетный файл, и когда я запускал скрипт, переименование успешно но с предупреждением

Моя партия сценарий:

@echo off 
set count=0 
:: Getting number of files 
for %%x in (folder\*.html) do (set /a count+=1) 

:: Renaming files 
for /l %%a in (1,1,%count%) do (ren folder\*.html data_%%a.xls) 
pause 

Предупреждение

A duplicate file name exists, or the file cannot be found. 
A duplicate file name exists, or the file cannot be found. 
A duplicate file name exists, or the file cannot be found. 
Press any key to continue . . . 

, что случилось? благодаря, прежде чем :)

Answer 1

вы просите, чтобы переименовать все файлы в папке сразу (ren folder\*.html data_%%a.xls)

так все * .html будут переименовывать в data_1.xls.

вам нужен цикл для переименования файлов по одному.

Answer 2

Вы должны объединить петлю:

@echo off 
setlocal 
set "count=0" 
for %%x in (folder\*.html) do (
    set /a "count+=1" 
    call ren "%%x" "data_%%count%%.xls" 
) 
endlocal 
pause 

Answer 3

попробовать это:

:: Renaming files 
for %%a in (folder\*.html) do (
    set /a count+=1 
    set "fname=%%~a" 
    setlocal enabledelayedexpansion 
    ren "!fname!" data_!count!.xls 
    endlocal 
) 

и решение без delayed expansion:

for /f "tokens=1*delims=:" %%a in ('dir /b /a-d folder\*.html^|findstr /n $') do ren "folder\%%~b" data_%%a.xls