Excell 2007 выровнять по столбцам по идентификационному номеру

Question

Я пытаюсь выровнять/сопоставлять несогласованные данные в excel. В настоящее время данные выглядит следующим образом:

customerid customerid2 emailaddress   firstname   lastname 

1   2   bobhope@.com   Chris    Anderson 
2   1   chrisanderson@.com Bob    Hope 
7   8   Bryansmoth@.com  Jenn    Lacy 
8   7   Jennlacy@.com   Bryan    Smoth 
9      123@.com 
10   11   RonnieWilliams@.com Andrew   Smoth 
11   10   Andrewsmoth@.com  Ronnie   Williams 

В основном я пытаюсь получить столбец А и Б идентификаторами, чтобы соответствовать соответствующим образом и все данные справа выровнять. Так оно и делается:

1   1   bobhope@.com   Bob    Hope 
2   2   chrisanderson@.com Chris    Anderson 
7   7   Bryansmoth@.com  Bryan    Smoth 
8   8   Jennlacy@.com   Jenn    Lacy 
9      123@.com 
10   10   RonnieWilliams@.com Ronnie   Williams 
11   11   Andrewsmoth@.com  Andrew   Smoth 

Я бы сделал это вручную, но есть 17 000 неправильных записей. Насколько я понимаю, я могу запустить VBA в excel, который поможет исправить эту проблему. Я не могу подчеркнуть, насколько я ценю любую помощь!

Большое спасибо

Answer 1

Я обычно не дают код так скоро, но это, казалось, интересный вопрос. Попробуйте этот простой код.

Мои предположения:

1. Название листа, который имеет данные, называется Sheet1
2. Данные в Columns A:E
3. Там нет кратных вхождений customerid2
4. Row 1 имеет заголовки

Logic:

1. магазин диапазон B:E в массиве
2. Очистить столбцы B:E для вывода
3. Loop хотя Col A и сравнить его с седловины 1 массива, и если совпадение найдено затем заполнить соответствующую строку

Код:

Я прокомментировал код. Тем не менее, если вы столкнулись с проблемой, просто отправьте ее обратно.

Option Explicit 

Sub Sample() 
    Dim ws As Worksheet 
    Dim rng As Range 
    Dim MyData As Variant 
    Dim i As Long, j As Long, lRow As Long 

    '~~> This is your relevant sheet 
    Set ws = ThisWorkbook.Sheets("Sheet1") 

    With ws 
     '~~> get the last row which has data 
     lRow = .Range("A" & .Rows.Count).End(xlUp).Row 

     '~~> Get your Col B:E Range 
     Set rng = ws.Range("B2:E" & lRow) 

     '~~> Store the range in an array 
     MyData = rng 

     '~~> Clear Col B:E for output 
     rng.ClearContents 

     '~~> Loop through Col A 
     For i = 2 To lRow 
      '~~> Loop through Array 
      For j = LBound(MyData) To UBound(MyData) 
       '~~> If match found then write to relevant row 
       If MyData(j, 1) = .Range("A" & i).Value Then 
        .Range("B" & i).Value = MyData(j, 1) 
        .Range("C" & i).Value = MyData(j, 2) 
        .Range("D" & i).Value = MyData(j, 3) 
        .Range("E" & i).Value = MyData(j, 4) 
        Exit For 
       End If 
      Next j 
     Next i 
    End With 
End Sub 

Скриншот (до и после):