Как получить значение столбца, не зная имя столбца? SQL Server

Question

У меня есть имя таблицы @Table_Name

У меня есть столбец значение, как @Value, но не имеют имя столбца (но есть в 1-м положении и может быть Seek_id или prov_id ... Я должен сравнить свое значение с этим id)

Как сравнить значение имени столбца таблицы?

Я хочу что-то вроде

SELECT * FROM @Table_Name 
WHERE Table.Column[1].Value = @Value 

, например @Table_Name = bb_match и @Value = 6

Answer 1

Возможное это будет полезно для вас -

Запрос:

IF OBJECT_ID (N'dbo.bb_match') IS NOT NULL 
    DROP TABLE dbo.bb_match 

CREATE TABLE dbo.bb_match (seek_id INT, prov_id INT) 

INSERT INTO dbo.bb_match (seek_id, prov_id) 
VALUES (6, 1), (2, 6) 

DECLARE 
     @ColumnID TINYINT 
    , @Value INT 
    , @TableName SYSNAME 
    , @SQL NVARCHAR(500) 

SELECT 
     @ColumnID = 1 
    , @Value = 6 
    , @TableName = 'dbo.bb_match' 

SELECT @SQL = 'SELECT * FROM ' + @TableName + ' WHERE [' + c.name + '] = ' + CAST(@Value AS NVARCHAR(MAX)) 
FROM sys.objects o WITH (NOWAIT) 
JOIN sys.schemas s WITH (NOWAIT) ON o.[schema_id] = s.[schema_id] 
JOIN sys.columns c WITH (NOWAIT) ON o.[object_id] = c.[object_id] 
WHERE o.[type] = 'U' -- <-- only for tables columns 
    AND s.name + '.' + o.name = @TableName 
    AND c.column_id = @ColumnID 

PRINT @SQL 

EXEC sp_executesql @SQL 

Более короткий, но небезопасный (sys.columns содержит column_name для таблиц, представлений, процедур, ...):

SELECT @SQL = 'SELECT * FROM ' + @TableName + ' WHERE [' + c.name + '] = ' + CAST(@Value AS NVARCHAR(MAX)) 
FROM sys.columns c WITH (NOWAIT) 
WHERE c.[object_id] = OBJECT_ID(@TableName) 
    AND c.column_id = @ColumnID 

EXEC sys.sp_executesql @SQL

Выход:

SELECT * FROM dbo.bb_match WHERE [seek_id] = 6 

Результаты:

seek_id  prov_id 
----------- ----------- 
6   1 

Answer 2

declare @sql varchar(MAX) 
declare @tablename varchar(100) = 'MyTable' --add your table name here 
declare @value varchar(100) = 'SomeValue' -- add your desired value hree 

select @sql = 'SELECT * FROM ' + @tablename + ' WHERE ' 
+ name 
+ ' = ''' + @value + '''' 
from sys.columns where object_id = object_id(@tablename) and column_id = 1 

exec (@sql) 

Для этого есть три части. Сначала я объявляю три строки. @sql - это то, где я буду строить запрос, @tablename и @value - это таблица и значение поиска для поиска в/для. Я включил фиктивные значения MyTable и SomeValue, чтобы показать, что я говорю о

Далее я создаю заявление sql. Первая строка устанавливает строку как SELECT * FROM MyTable WHERE

Я затем добавить в имени столбца, выбрав имя из таблицы sys.columns SQL-серверной системы, фильтрации на первой колонке (column_id = 1) и имени таблицы

Следующий шаг для добавления значения, которое мы хотим найти в столбце.

Наконец, EXEC(@sql) интерпретирует строку как команду и запускает ее.