Delphi - Обнаружение нажатия 3 клавиши одновременно

Question

Я хочу, чтобы обнаружить нажатие 3 ключа в моей форме, например Ctrl +C + N ... набранный форму мне нужно обнаружить всегда начинается с Ctrl и далее идут две буквы.

Как я это делаю?

Answer 1

По прибытии одного из ключей вы можете посмотреть, был ли другой ключ уже выключен. Например .:

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word; 
    Shift: TShiftState); 
begin 
    if Shift = [ssCtrl] then begin 
    case Key of 
     Ord('C'): 
     if (GetKeyState(Ord('N')) and $80) = $80 then 
      ShowMessage('combo'); 
     Ord('N'): 
     if (GetKeyState(Ord('C')) and $80) = $80 then 
      ShowMessage('combo'); 
    end; 
    end; 
end; 

Однако это будет также обнаружить, например N + Ctrl + C, последовательность, которая не начинается с ключа Ctrl. Если это не относится к действительной комбинации клавиш, вы можете сохранить немного ключевой истории с помощью флага. Далее следует обнаружить только последовательности, которые изначально начинается с Ctrl:

type 
    TForm1 = class(TForm) 
    procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState); 
    procedure FormKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState); 
    private 
    FValidKeyCombo: Boolean; 
    end; 

... 

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word; 
    Shift: TShiftState); 
begin 
    if FValidKeyCombo and (Shift = [ssCtrl]) then 
    case Key of 
     Ord('C'): 
     if (GetKeyState(Ord('N')) and $80) = $80 then 
      ShowMessage('combo'); 
     Ord('N'): 
     if (GetKeyState(Ord('C')) and $80) = $80 then 
      ShowMessage('combo'); 
    end; 
    FValidKeyCombo := (Shift = [ssCtrl]) and (Key in [Ord('C'), Ord('N')]); 
end; 

procedure TForm1.FormKeyUp(Sender: TObject; var Key: Word; Shift: TShiftState); 
begin 
    FValidKeyCombo := False; 
end; 

Answer 2

Существует более простой способ:

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState); 
    begin 
     If (GetKeyState(Ord('Q'))<0) and (GetKeyState(Ord('N'))<0) and (GetKeyState(VK_CONTROL)<0) 
      Then ShowMessage('You did it :)'); 
    End;