SQL Server: выход фильтра sp_who2

Question

В SQL Server существует ли простой способ фильтрации вывода sp_who2? Например, я хотел просто показать строки для определенной базы данных, например.

Answer 1

Вы могли бы попробовать что-то вроде

DECLARE @Table TABLE(
     SPID INT, 
     Status VARCHAR(MAX), 
     LOGIN VARCHAR(MAX), 
     HostName VARCHAR(MAX), 
     BlkBy VARCHAR(MAX), 
     DBName VARCHAR(MAX), 
     Command VARCHAR(MAX), 
     CPUTime INT, 
     DiskIO INT, 
     LastBatch VARCHAR(MAX), 
     ProgramName VARCHAR(MAX), 
     SPID_1 INT, 
     REQUESTID INT 
) 

INSERT INTO @Table EXEC sp_who2 

SELECT * 
FROM @Table 
WHERE .... 

И фильтровать то, что вам требуется.

Answer 2

Один из способов создать временную таблицу:

CREATE TABLE #sp_who2 
(
    SPID INT, 
    Status VARCHAR(1000) NULL, 
    Login SYSNAME NULL, 
    HostName SYSNAME NULL, 
    BlkBy SYSNAME NULL, 
    DBName SYSNAME NULL, 
    Command VARCHAR(1000) NULL, 
    CPUTime INT NULL, 
    DiskIO INT NULL, 
    LastBatch VARCHAR(1000) NULL, 
    ProgramName VARCHAR(1000) NULL, 
    SPID2 INT 
) 
GO 

INSERT INTO #sp_who2 
EXEC sp_who2 
GO 

SELECT * 
FROM #sp_who2 
WHERE Login = 'bla' 
GO 

DROP TABLE #sp_who2 
GO 

Answer 3

Да, захватывая вывод sp_who2 в таблицу, а затем выбрать из таблицы, но это было бы плохой способ сделать это. Во-первых, потому что sp_who2, несмотря на свою популярность, имеет недокументированную процедуру, и вы не должны полагаться на недокументированные процедуры. Во-вторых, все, что может сделать sp_who2 и многое другое, можно получить от sys.dm_exec_requests и других DMV, а показ может быть отфильтрован, упорядочен, объединен и все остальные лакомства, которые поставляются с запрограммированными наборами строк.

Answer 4

Существует немало хороших хранимых процедур sp_who3. Я уверен, что Adam Machanic сделал действительно хороший, AFAIK.

Адам называет Кто: http://sqlblog.com/blogs/adam_machanic/archive/tags/Scripts/default.aspx

Answer 5

на основе http://sqlserver2005.databases.aspfaq.com/how-do-i-mimic-sp-who2.html

я создал следующий скрипт,
который разрешает находить активные соединения с любым datbase с помощью DMV это работает под SQL 2005, 2008 и 2008R2

После скрипт использует sys.dm_exec_sessions, sys.dm_exec_requests, sys.dm_exec_connections, sys.dm_tran_locks

Declare @dbName varchar(1000) 
set @dbName='abc' 

;WITH DBConn(SPID,[Status],[Login],HostName,DBName,Command,LastBatch,ProgramName) 
As 
(
SELECT 
    SPID = s.session_id, 
    Status = UPPER(COALESCE 
     (
      r.status, 
      ot.task_state, 
      s.status, 
     '')), 
    [Login] = s.login_name, 
    HostName = COALESCE 
     (
      s.[host_name], 
      ' .' 
     ), 
    DBName = COALESCE 
     (
      DB_NAME(COALESCE 
      (
       r.database_id, 
       t.database_id 
      )), 
      '' 
     ), 
    Command = COALESCE 
     (
      r.Command, 
      r.wait_type, 
      wt.wait_type, 
      r.last_wait_type, 
      '' 
     ), 
    LastBatch = COALESCE 
     (
      r.start_time, 
      s.last_request_start_time 
     ), 
    ProgramName = COALESCE 
     (
      s.program_name, 
      '' 
     ) 
FROM 
    sys.dm_exec_sessions s 
LEFT OUTER JOIN 
    sys.dm_exec_requests r 
ON 
    s.session_id = r.session_id 
LEFT OUTER JOIN 
    sys.dm_exec_connections c 
ON 
    s.session_id = c.session_id 
LEFT OUTER JOIN 
(
    SELECT 
     request_session_id, 
     database_id = MAX(resource_database_id) 
    FROM 
     sys.dm_tran_locks 
    GROUP BY 
     request_session_id 
) t 
ON 
    s.session_id = t.request_session_id 
LEFT OUTER JOIN 
    sys.dm_os_waiting_tasks wt 
ON 
    s.session_id = wt.session_id 
LEFT OUTER JOIN 
    sys.dm_os_tasks ot 
ON 
    s.session_id = ot.session_id 
LEFT OUTER JOIN 
(
    SELECT 
     ot.session_id, 
     CPU_Time = MAX(usermode_time) 
    FROM 
     sys.dm_os_tasks ot 
    INNER JOIN 
     sys.dm_os_workers ow 
    ON 
     ot.worker_address = ow.worker_address 
    INNER JOIN 
     sys.dm_os_threads oth 
    ON 
     ow.thread_address = oth.thread_address 
    GROUP BY 
     ot.session_id 
) tt 
ON 
    s.session_id = tt.session_id 
WHERE 
    COALESCE 
    (
     r.command, 
     r.wait_type, 
     wt.wait_type, 
     r.last_wait_type, 
     'a' 
    ) >= COALESCE 
    (
     '', 
     'a' 
    ) 
) 

Select * from DBConn 
where DBName like '%'+@dbName+'%' 

Answer 6

Незначительное улучшение ответа ответчика. Я хотел поставить свои критерии в верхней части, и сделать его легче повторно использовать изо дня в день:

DECLARE @Spid INT, @Status VARCHAR(MAX), @Login VARCHAR(MAX), @HostName VARCHAR(MAX), @BlkBy VARCHAR(MAX), @DBName VARCHAR(MAX), @Command VARCHAR(MAX), @CPUTime INT, @DiskIO INT, @LastBatch VARCHAR(MAX), @ProgramName VARCHAR(MAX), @SPID_1 INT, @REQUESTID INT 

    --SET @SPID = 10 
    --SET @Status = 'BACKGROUND' 
    --SET @LOGIN = 'sa' 
    --SET @HostName = 'MSSQL-1' 
    --SET @BlkBy = 0 
    --SET @DBName = 'master' 
    --SET @Command = 'SELECT INTO' 
    --SET @CPUTime = 1000 
    --SET @DiskIO = 1000 
    --SET @LastBatch = '10/24 10:00:00' 
    --SET @ProgramName = 'Microsoft SQL Server Management Studio - Query' 
    --SET @SPID_1 = 10 
    --SET @REQUESTID = 0 

    SET NOCOUNT ON 
    DECLARE @Table TABLE(
      SPID INT, 
      Status VARCHAR(MAX), 
      LOGIN VARCHAR(MAX), 
      HostName VARCHAR(MAX), 
      BlkBy VARCHAR(MAX), 
      DBName VARCHAR(MAX), 
      Command VARCHAR(MAX), 
      CPUTime INT, 
      DiskIO INT, 
      LastBatch VARCHAR(MAX), 
      ProgramName VARCHAR(MAX), 
      SPID_1 INT, 
      REQUESTID INT 
    ) 
    INSERT INTO @Table EXEC sp_who2 
    SET NOCOUNT OFF 
    SELECT * 
    FROM @Table 
    WHERE 
    (@Spid IS NULL OR SPID = @Spid) 
    AND (@Status IS NULL OR Status = @Status) 
    AND (@Login IS NULL OR Login = @Login) 
    AND (@HostName IS NULL OR HostName = @HostName) 
    AND (@BlkBy IS NULL OR BlkBy = @BlkBy) 
    AND (@DBName IS NULL OR DBName = @DBName) 
    AND (@Command IS NULL OR Command = @Command) 
    AND (@CPUTime IS NULL OR CPUTime >= @CPUTime) 
    AND (@DiskIO IS NULL OR DiskIO >= @DiskIO) 
    AND (@LastBatch IS NULL OR LastBatch >= @LastBatch) 
    AND (@ProgramName IS NULL OR ProgramName = @ProgramName) 
    AND (@SPID_1 IS NULL OR SPID_1 = @SPID_1) 
    AND (@REQUESTID IS NULL OR REQUESTID = @REQUESTID) 

Answer 7

очень простой способ сделать это, чтобы создать ссылку ODBC в EXCEL и запустить sp_who2 оттуда.

Вы можете обновлять, когда захотите, и потому, что это EXCEL, все можно легко манипулировать!

Answer 8

Вы можете save the results into a temp table, но было бы еще лучше, чтобы перейти непосредственно к источнику на master.dbo.sysprocesses

Я построил это выход почти точно то же самое, что sp_who2 генерирует, за исключением того, что вы можете легко добавить ORDER BY и WHERE статьи, чтобы получить значимый результат.

SELECT spid, 
     sp.[status], 
     loginame [Login], 
     hostname, 
     blocked BlkBy, 
     sd.name DBName, 
     cmd Command, 
     cpu CPUTime, 
     physical_io DiskIO, 
     last_batch LastBatch, 
     [program_name] ProgramName 
FROM master.dbo.sysprocesses sp 
JOIN master.dbo.sysdatabases sd ON sp.dbid = sd.dbid 
ORDER BY spid 

Answer 9

Подобный KyleMit ответ, его можно непосредственно выбрать таблицы, используемые sp_who2, хотя я думаю, что это нужно только таблицу dbo.sysprocesses.

Если кто-то откроет этот СП, он может понять, что он делает. Это мой лучший выбор, чтобы иметь такой же вывод, как sp_who2

select convert(char(5),sp.spid) as SPID 
     , CASE lower(sp.status) 
       When 'sleeping' Then lower(sp.status) 
       Else upper(sp.status) 
       END as Status 
     , convert(sysname, rtrim(sp.loginame)) as LOGIN 
     , CASE sp.hostname 
       When Null Then ' .' 
       When ' ' Then ' .' 
       Else rtrim(sp.hostname) 
       END as HostName 
     , CASE isnull(convert(char(5),sp.blocked),'0') 
       When '0' Then ' .' 
       Else isnull(convert(char(5),sp.blocked),'0') 
       END as BlkBy 
     , case when sp.dbid = 0 then null when sp.dbid <> 0 then db_name(sp.dbid) end as DBName 
     , sp.cmd as Command 
     , sp.cpu as CPUTime 
     , sp.physical_io as DiskIO 
     , sp.last_batch as LastBatch 
     , sp.program_name as ProgramName 
     from master.dbo.sysprocesses sp (nolock) 
    ; 

За этот выбор, вы можете выбрать поля, которые необходимы и имеют порядок вы хотите.

Answer 10

Это решение для Вас: http://blogs.technet.com/b/wardpond/archive/2005/08/01/the-openrowset-trick-accessing-stored-procedure-output-in-a-select-statement.aspx

select * from openrowset ('SQLOLEDB', '192.168.x.x\DATA'; 'user'; 'password', 'sp_who') 

Answer 11

Расширение первого и лучшего ответа ... Я создал хранимую процедуру на основной базе данных, которые затем можно передать параметры .. такие как имя базы данных:

USE master 
GO 

CREATE PROCEDURE sp_who_db 
(
    @sDBName varchar(200) = null, 
    @sStatus varchar(200) = null, 
    @sCommand varchar(200) = null, 
    @nCPUTime int   = null 
) 
AS 
DECLARE @Table TABLE 
(
    SPID INT, 
    Status VARCHAR(MAX), 
    LOGIN VARCHAR(MAX), 
    HostName VARCHAR(MAX), 
    BlkBy VARCHAR(MAX), 
    DBName VARCHAR(MAX), 
    Command VARCHAR(MAX), 
    CPUTime INT, 
    DiskIO INT, 
    LastBatch VARCHAR(MAX), 
    ProgramName VARCHAR(MAX), 
    SPID_1 INT, 
    REQUESTID INT 
) 

INSERT INTO @Table EXEC sp_who2 

SELECT * 
    FROM @Table 
    WHERE (@sDBName IS NULL OR DBName = @sDBName) 
    AND  (@sStatus IS NULL OR Status = @sStatus) 
    AND  (@sCommand IS NULL OR Command = @sCommand) 
    AND  (@nCPUTime IS NULL OR CPUTime > @nCPUTime) 
GO 

я мог бы продлить его, чтобы добавить заказ параметра или даже убить paramatmer так оно убивает все подключения к определенным данным