Как передать объекты между функциями?

Question

Предположим, у меня есть функция:

function someFunction: TStringList; 
begin 
    result:=TStringList.Create; 
    if someConditionIsTrue then 
    result:=doSomething; 
    //other code 
end; 

и функция DoSomething:

function doSomething: TStringList; 
begin 
    result:=TStringList.Create; 
    result.Add(something); 
end; 

Если я запускаю этот код все работает, как хотелось бы, но я все еще интересно, если это «правильный» способ обхода объекта, например, строкового списка?

Строчные списки никогда не освобождаются, и я задаюсь вопросом, может ли процесс обхода объектов стать сложным или запутанным, когда дело доходит до отладки или кто-то еще пытается понять код.

Answer 1

«Правильный» подход заключается в том, чтобы вы установили свои собственные правила для того, как вещи будут уничтожены. Хорошо создавать объекты в результате функции, но только если вы выполняете свои собственные строгие правила.

В вашем случае SomeFunction имеет утечку памяти. Сначала вы создаете TStringList, а затем, если какое-либо условие выполнено, вы создаете на своем месте еще один TStringList, полностью игнорируя первый. Таким образом, утечка памяти.

DoSomething не должен быть функцией, возвращающей список строк, если есть вероятность, что у вас уже есть один созданный. Вместо этого, просто сделать это процедура ...

procedure DoSomething(AList: TStringList); 
begin 
    AList.Add(Something); 
end; 

После того, как вы сделаете это, то SomeFunction должен выглядеть следующим образом:

function someFunction: TStringList; 
begin 
    Result:= TStringList.Create; 
    if someConditionIsTrue then 
    DoSomething(Result); 
    //other code 
end; 

"В stringlists никогда не освобожденный"

I надеюсь, что это не по дизайну. Все, что вы создаете, должно быть свободным в какой-то момент, особенно если у вас есть функции, которые создают их результат. Единственное исключение - если вы создаете что-то, что живет в течение всего срока действия приложения, и даже тогда это крайняя распространенность, чтобы освободить их в любом случае.

---

На этой ноте, единственный раз, когда я когда-либо создать объект в результате функции, когда я герметизирующего несколько строк кода, которые иначе были бы дублируется много раз. Например, создание запроса.

Вместо того чтобы повторять этот код ...

Q:= TADOQuery.Create(nil); 
Q.Connection:= MyDatabaseConnection; 
Q.SetSomeOtherProperties; 

... Я положил его в функцию ...

function CreateQuery: TADOQuery; 
begin 
    Result:= TADOQuery.Create(nil); 
    Result.Connection:= MyDatabaseConnection; 
    Result.SetSomeOtherProperties; 
end; 

Тогда, я могу просто вызвать эту функцию всякий раз, когда мне нужно повторить этот код ...

Q:= CreateQuery; 

Answer 2

В stringlists никогда освобожден

Это проблема сама по себе. Как было отмечено в комментариях, это создает утечки памяти. В общем, я нахмурился над функциями, которые создают объекты и дают право собственности через их результаты.Когда мне это нужно, я обычно называю свою функцию "Create*", чтобы сделать ее максимально явной, чтобы вызывающая сторона отвечала за освобождение памяти.

С этим сказанным, более элегантный шаблон для достижения того, что вам нужно:

procedure someFunction; 
var vStrings : TStringList; 
begin 
    vStrings := TStringList.Create; 
    try 
    if someConditionIsTrue then 
     doSomething(vStrings); 
    //other code 
    finally 
    vStrings.Free; 
    end; 
end; 

procedure doSomething(AStrings : TStringList); 
begin 
    AStrings.Add(something); 
end; 

Если вам действительно нужен ваш «SomeFunction», чтобы вернуть TStringList и не хотите, чтобы получить один с помощью параметра, здесь, как правильно управлять им, чтобы избежать утечек памяти.

function CreateAndInitStrings : TStringList; 
begin 
    Result := TStringList.Create; 
    try 
    if someConditionIsTrue then 
     doSomething(Result); 
    //other code 
    except 
    Result.Free; 
    raise; 
    end; 
end;