AWK: добавление нового поля из другого файла

Question

У меня есть файл с разделителем «@». Он имеет повторяющиеся данные, которые можно использовать для разделения файла в разделах. В другом файле у меня есть данные, которые я хотел бы добавить в качестве первого столбца в первый файл. Источник добавленных данных будет зацикливаться с каждым экземпляром повторяющихся данных из первого файла. Файлы выглядят следующим образом:

Файл 1

Race1@300Yards@6 
Race2@300Yards@7 
Race3@250Yards@7 
Race4@250Yards@7 
Race5@250Yards@8 
Race6@250Yards@9 
Race7@300Yards@10 
Race8@300Yards@12 
Race1@330Yards@10 
Race2@300Yards@10 
Race3@300Yards@10 
Race4@300Yards@10 
Race5@11/2Miles@11 
Race6@7Miles@9 
Race7@6Miles@8 
Race8@51/2Miles@7 
Race9@1Mile@8 
Race10@51/2Miles@12 
Race1@61/2Miles@6 
Race2@11/16Miles@9 
Race3@1Mile@9 
Race4@11/2Miles@6 
Race5@11/16Miles@10 
Race6@1Mile@10 
Race7@11/16Miles@12 
Race8@1Mile@12 

Другой файл выглядит следующим образом:

Файл 2

London 
New York 
Dallas 

Желаемые результаты выглядят так:

Race1@300Yards@6@London 
Race2@300Yards@7@London 
Race3@250Yards@7@London 
Race4@250Yards@7@London 
Race5@250Yards@8@London 
Race6@250Yards@9@London 
Race7@300Yards@10@London 
Race8@300Yards@12@London 
Race1@330Yards@10@New York 
Race2@300Yards@10@New York 
Race3@300Yards@10@New York 
Race4@300Yards@10@New York 
Race5@11/2Miles@11@New York 
Race6@7Miles@9@New York 
Race7@6Miles@8@New York 
Race8@51/2Miles@7@New York 
Race9@1Mile@8@New York 
Race10@51/2Miles@12@New York 
Race1@61/2Miles@6@Dallas 
Race2@11/16Miles@9@Dallas 
Race3@1Mile@9@Dallas 
Race4@11/2Miles@6@Dallas 
Race5@11/16Miles@10@Dallas 
Race6@1Mile@10@Dallas 
Race7@11/16Miles@12@Dallas 
Race8@1Mile@12@Dallas 

Я знаю что awk можно использовать для разделения места гонки на «Race1». Я думаю, он начинает что-то вроде:

awk '/Race1/{x="Race"++i;}{print $5= something relating to file 2} 

Кто-нибудь знает, как анализировать, используя AWK, или любой другой команды Linux, для двух файлов с помощью петель и условий?

Answer 1

Если вы сохраните это как a.awk

BEGIN { 
    FS = OFS = "@" 
    i = 0 
    j = -1 
} 
NR == FNR { 
    a[i++] = $1   
} 
NR != FNR { 
    if ($1 == "Race1") 
     j++   
    $4 = a[j] 
    print  
} 

и запустить

awk -f a.awk file2 file1 

вы получите желаемые результаты.

Выход

Race1@300Yards@6@London 
Race2@300Yards@7@London 
Race3@250Yards@7@London 
Race4@250Yards@7@London 
Race5@250Yards@8@London 
Race6@250Yards@9@London 
Race7@300Yards@10@London 
Race8@300Yards@12@London 
Race1@330Yards@10@New York 
Race2@300Yards@10@New York 
Race3@300Yards@10@New York 
Race4@300Yards@10@New York 
Race5@11/2Miles@11@New York 
Race6@7Miles@9@New York 
Race7@6Miles@8@New York 
Race8@51/2Miles@7@New York 
Race9@1Mile@8@New York 
Race10@51/2Miles@12@New York 
Race1@61/2Miles@6@Dallas 
Race2@11/16Miles@9@Dallas 
Race3@1Mile@9@Dallas 
Race4@11/2Miles@6@Dallas 
Race5@11/16Miles@10@Dallas 
Race6@1Mile@10@Dallas 
Race7@11/16Miles@12@Dallas 
Race8@1Mile@12@Dallas 

Объяснение

Начнем с настройки полей ввода и вывода разделители @. Мы также инициализируем наши переменные i, j, которые будут использоваться в качестве индексов массива.

Первое условие проверяет, проходим ли мы через файл2 с NR == FNR. Во время первого блока мы связываем индекс i с первым полем, которое является названием города. Затем мы увеличиваем i.

Второе условие проверяет, проходим ли мы через файл2 с NR != FNR. Если первое поле равно Race1, то мы увеличиваем j (обратите внимание, что мы инициализировали j равным -1). Мы устанавливаем 4-е поле a[j], а затем печатаем линию.