Как вызвать макрос после нажатия кнопки «Обновить» или «Обновить все»?

Question

В конечном счете, я хотел бы запустить макрос после того, как кто-нибудь обновит книгу, особенно используя кнопку «Обновить» на вкладке «Данные» в Excel. Однако пока я был бы доволен только тем, чтобы активировать события BeforeRefresh или AfterRefresh QueryTable, нажав кнопку «Обновить».

В дополнение к «документации», предлагаемых на веб-сайте Microsoft Dev Center, соответствующие должности, которые я прочитал, как часть этого процесса исследования включают в себя:

• Excel VBA - QueryTable AfterRefresh function not being called after Refresh completes
• VBA For Excel AfterRefresh Event
• Есть другие менее полезные или соответствующие должности, но мне не хватает репутации, чтобы публиковать их здесь.

У меня явно отсутствует что-то важное (и, скорее всего, очевидное). Вот то, что я до сих пор:

модули Под класса (qtclass)

Option Explicit 

Private WithEvents qt As Excel.QueryTable 

Private Sub qt_AfterRefresh(ByVal Success As Boolean) 

    MsgBox "qt_AfterRefresh called sucessfully." 
    If Success = True Then 
     Call Module2.SlicePivTbl 
     MsgBox "If called succesfully." 
    End If 

End Sub 

Private Sub qt_BeforeRefresh(Cancel As Boolean) 
    MsgBox "qt_BeforeRefresh called." 
End Sub 

Под модулем ThisWorkbook

Private Sub Workbook_Open() 

    Dim qtevent As qtclass 
    Dim qt As QueryTable 
    Set qt = ThisWorkbook.Worksheets("Data-Fund").ListObjects(1).QueryTable 
    Set qtevent = New qtclass 

End Sub 

Я попытался вариации второго кодового блока в соответствии с конкретными рабочими листами, а также , но еще не найти ничего, что сработает. Нужно ли мне как-то смущать вопрос QueryTable в модуле Worksheet? Любые предложения или мысли о том, что мне не хватает, будут очень признательны.

Answer 1

Вы фактически не подключили таблицу запросов к экземпляру класса. Пересмотренный qtclass

Option Explicit 

Private WithEvents qt As Excel.QueryTable 
Public Property Set HookedTable(q As Excel.QueryTable) 
    Set qt = q 
End Property 

Private Sub qt_AfterRefresh(ByVal Success As Boolean) 

    MsgBox "qt_AfterRefresh called sucessfully." 
    If Success = True Then 
     Call Module2.SlicePivTbl 
     MsgBox "If called succesfully." 
    End If 

End Sub 

Private Sub qt_BeforeRefresh(Cancel As Boolean) 
    MsgBox "qt_BeforeRefresh called." 
End Sub 

код New ThisWorkbook:

Dim qtevent As qtclass 
Private Sub Workbook_Open() 

    Set qtevent = New qtclass 
    Set qtevent.HookedTable = ThisWorkbook.Worksheets("Data-Fund").ListObjects(1).QueryTable 

End Sub 

Обратите внимание, что это довольно тесно связаны между собой. Это было бы более пригодным для повторного использования, если бы вы поднимали события в классе и объявляли свою переменную ctevent WithEvents.