Скрыть строки на основе значения ячейки

Question

У меня есть таблица элементов и величин, где я хочу скрыть строки, когда количество равно 0. Макрос работает, но для завершения требуется слишком много времени.

Это код:

Sub Hide2ndFix() 
' 
' Hide2ndFix Macro 
' 
BeginRow = 414 
EndRow = 475 
ChkCol = 24 

    For RowCnt = BeginRow To EndRow 
     If Cells(RowCnt, ChkCol).Value = 0 Then 
      Cells(RowCnt, ChkCol).EntireRow.Hidden = True 
     End If 
    Next RowCnt 
' 
End Sub 

Есть более эффективный способ получить тот же результат, убежищ строк 414-475, если значение в столбце X является 0?

Answer 1

Обычный способ сделать любой код (который делает любое изменение в книге) быстрее является отключение screen updating и отключение events и изменение режима calculation к Manual (есть и другие способы, но эти 3 вещи, которые имеют наибольший коэффициент) ,

И все остальное состоит в том, что сбор всех строк в одном диапазоне объединений имеет большой фактор в удалении и вставке строк, потому что время, необходимое для удаления одной строки, похоже на время удаления всего диапазона объединения. Например, если для удаления одной строки требуется 1 секунда, то для удаления 1000 строк потребуется 1000 секунд, но для удаления диапазона объединения, содержащего 1000 строк, требуется только 1 секунда.

Попробуйте этот код:

Sub Hide2ndFix() 
' 
' Hide2ndFix Macro 
' 
Dim RowCnt As Long, uRng As Range 
Application.ScreenUpdating = False 
Application.EnableEvents = False 
Application.Calculation = xlCalculationManual 

BeginRow = 414 
EndRow = 475 
ChkCol = 24 

    For RowCnt = BeginRow To EndRow 
     If Cells(RowCnt, ChkCol).Value = 0 Then 
     If uRng Is Nothing Then 
      Set uRng = Cells(RowCnt, ChkCol) 
     Else 
      Set uRng = Union(uRng, Cells(RowCnt, ChkCol)) 
     End If 

     End If 
    Next RowCnt 
' 
If Not uRng Is Nothing Then uRng.EntireRow.Hidden = True 

Application.ScreenUpdating = True 
Application.EnableEvents = True 
Application.Calculation = xlCalculationAutomatic 

End Sub