Как добавить время и заменить его в файле на Perl?

Question

У меня есть следующий код для получения даты с сервера и отображения его в формате yy/mm/dd-hh/mm/ss.

#!/usr/bin/perl 
system(`date '+ %Y/%m/%d-%H:%M:%S' >ex.txt`); 
open(MYINPUTFILE, "/tmp/ranjan/ex.txt"); 
while(<MYINPUTFILE>) 
{ 
    chomp; 
    print "$_\n"; 
} 
close(MYINPUTFILE); 

выход:

2013/07/29-18:58:04 

Я хочу добавить две минуты времени, и нужно заменить время присутствующий в файле, Pls дать мне некоторые идеи.

Answer 1

Изменить команду даты, чтобы добавить 2 минуты:

date --date "+2 min" '+ %Y/%m/%d-%H:%M:%S' 

или версию Perl:

use POSIX; 
print strftime("%Y/%m/%d-%H:%M:%S", localtime(time + 120)); 

Answer 2

Лучше использовать Time::Piece сделать синтаксический анализ и форматирование дат. Это встроенный модуль и не требует установки.

Необычно, в этом случае строка даты/времени замены точно такая же, как и исходная строка, считанная из файла, поэтому модификация может быть выполнена на месте. Обычно общая длина файла изменяется, поэтому необходимо либо создать новый файл, либо удалить старый, либо прочитать весь файл в памяти и записать его снова.

Эта программа открывает файл для одновременного чтения/записи, считывает первую строку из файла, анализирует его с помощью Time::Piece, добавляет две минуты (120 секунд), снова ищет начало файла и печатает новую дату/время, отформатированное так же, как оригинал, обратно в файл.

use strict; 
use warnings; 
use autodie; 

use Time::Piece; 
my $format = '%Y/%m/%d-%H:%M:%S'; 

open my $fh, '+<', 'ex.txt'; 

my $date_time = <$fh>; 
chomp $date_time; 
$date_time = Time::Piece->strptime($date_time, $format); 

$date_time += 60 * 2; 

seek $fh, 0, 0; 
print $fh $date_time->strftime($format); 
close $fh; 

выход

2013/07/29-19:00:04