Как улучшить производительность двух сцепленных агрегатов в Neo4j запросе

Question

Предполагая, что у меня есть Neo4j график природы:

create (SK:Author {name:'Stephen King'}), (JK:Author {name:'J.K. Rowling'}), (DS:Author {name:'Dr. Seuss'}), (TS:Book {name:'The Stand'}), (HP:Book {name:'Harry Potter'}), (CH:Book {name:'Cat in the Hat'}), (SHINING:Book {name:'The Shining'}), (PAF:Genre {name:'Post-Apocalyptic fiction'}), (F:Genre {name:'Fantasy'}), (C:Genre {name:'Childrens'}), (HORROR:Genre {name:'Horror'}), (SK)<-[:WRITTEN_BY]-(TS)-[:CATEGORIZED_AS]->(PAF), (JK)<-[:WRITTEN_BY]-(HP)-[:CATEGORIZED_AS]->(F), (DS)<-[:WRITTEN_BY]-(CH)-[:CATEGORIZED_AS]->(C), (SK)<-[:WRITTEN_BY]-(SHINING)-[:CATEGORIZED_AS]->(HORROR) 

Neo4j консоль ссылка: http://console.neo4j.org/r/2d69kq

У меня есть около 53000 автора узлов, 6 миллионов книжных узлов и 9 000 жанровых узлов.

Для запроса, как:

match (b:Book)-[:WRITTEN_BY]->(a:Author) 
where a.name in ['Stephen King', 'J.K. Rowling'] 
with a, collect(b) as bs 
unwind bs as book 
match (g:Genre)<-[r:CATEGORIZED_AS]-(book) 
where id(g) in [13, 14, 15, 16] 
with a, count(distinct book) as book_count_author, collect(book) as bs 
unwind bs as book 
match (g:Genre)<-[r:CATEGORIZED_AS]-(book) 
where id(g) in [13, 14, 15, 16] 
return a.name, g.name, count(distinct book) as book_count_genre, book_count_author 

Это занимает примерно 12 секунд. Я попытался переписать запрос несколькими различными способами и использовать подсказки индексов, но не могу понять, как это сделать быстрее. Есть предположения? Очевидно, этот пример упрощен, но у меня есть указатели на соответствующие свойства.

Вот пример результат из сцепленных агрегатов:

мне нужно два скопления. Первый - это количество книг авторов, ограниченное указанными жанрами во втором матче. Второй подсчет книг по каждому автору в каждом жанре, опять же ограничен одним и тем же жанром.

Answer 1

Если предположить, что у вас есть индекс (или существование ограничений) на: Author.name, вы, вероятно, может использовать это:

match (book:Book)-[:WRITTEN_BY]->(a:Author) 
where a.name in ['Stephen King', 'J.K. Rowling'] 
with a, book 
match (g:Genre)<-[:CATEGORIZED_AS]-(book) 
return a, g, size((g)<-[:CATEGORIZED_AS]-()) as book_count_genre, count(book) as book_count_author 

Сбор и размотки может быть дорогим, старайтесь избегать его, где вы можете. Обратите внимание, что вы можете найти размер шаблона, чтобы получить счет шаблона, который в противном случае не был бы восстановлен путем подсчета на узле с учетом ваших столбцов.

EDIT

Модифицированного запрос для осветленных требований

book_count_genre - количество книг с этим жанром любого автором

book_count_author - количество книг с этим жанром, написанного данным автором

Answer 2

Что @InverseFalcon сказал.

Вы можете оптимизировать его немного дальше:

MATCH (g:Genre)<-[r:CATEGORIZED_AS]-(book:Book)-[:WRITTEN_BY]->(a:Author) 
WHERE a.name in ['Stephen King', 'J.K. Rowling'] 
    AND g.name IN ['Post-Apocalyptic fiction','Childrens','Horror','Fantasy'] 
WITH a, g, count(distinct book) as book_count_author_genre 
RETURN a.name, collect({ genre: g.name, count: book_count_author_genre}), 
     sum(book_count_author_genre) as book_count_author 

Вам может понадобиться использовать индекс-подсказки для авторов и жанров

Если вы используете идентификаторы для Lookup это будет быстрее.