приложение определены или объект, определенная ошибка [при прохождении объекта Range к методу Range]

Question

Я копирование диапазона от одного листа к другому, используя следующий код:

Private Sub btn_Milestones_Click() 
Dim projectref As String 
Dim savelocation As String 
Dim projectSearchRange As Range 
Dim LastRow As Integer 
Dim NewWorkbook As Workbook 
Dim copy_range As Range 

'set search value (porject key - unique) 
projectref = cmb_Project.Value 

Application.ScreenUpdating = False 
Workbooks("Project tracker spreadsheet VBA").Activate 
'find the project reference in the tracking spreadsheet 
With Sheets("Project Tracking") 
    Set projectSearchRange = .Range("A:A").Find(projectref, , xlValues, xlWhole) 
    If Not projectSearchRange Is Nothing Then '<-- verify that find was successful 
     LastRow = projectSearchRange.Row 
     'file directory to save the new workbook in 
     savelocation = .Cells(LastRow, 5).Value 
    Else '<-- find was unsuccessful 
     MsgBox "Unable to find " & projectref 
     Exit Sub 
    End If 
End With 
Set copy_range = Range(Cells(LastRow, 11), Cells(LastRow, 34)) 

Worksheets("Milestone_Template").Range(copy_range).Copy 'application defined or object defined error occurs here 
Worksheets("Project Tracking").Range("A7:X7").PasteSpecial Paste:=xlPasteValues 

Application.CutCopyMode = False 
End Sub 

В качестве кода иллюстрирует, я ищет уникальный ссылочный номер в листе «Отслеживание проектов», затем используя номер строки, чтобы определить диапазон для копирования. копируя этот диапазон и вставляя значения этого диапазона в новый лист. Тем не менее, я получаю ошибку приложения в строке, указанной в коде. Я проверял тройку, чтобы убедиться, что имена рабочих листов верны.

У меня такое чувство, что я должен знать, как я объявляю диапазон и как он пытается скопировать значения, но я не вижу, откуда он может выбросить эту ошибку.

Может ли кто-нибудь увидеть, откуда я буду получать эту ошибку, и что мне нужно сделать, чтобы решить эту проблему?

Спасибо.

Answer 1

Извините, что вас избили, я редактировал заголовок вопроса, чтобы ваша конкретная проблема была идентифицирована. Вот попытка ответа ...

Это довольно сложно отлаживать без данных, но похоже, что copy_range уже имеет тип Range, вы, похоже, используете его в проблемной строке, как это было в диапазоне String, например, «A1 : С3" . Поэтому я переписал, вы можете перейти прямо к copy_range.Copy.

Ответы правильны, что полная квалификация помогает прояснить проблемы, поэтому я сделал некоторую полную квалификацию, но не все.

Попробуйте

Option Explicit 

Private Sub btn_Milestones_Click() 
    Dim projectref As String 
    Dim savelocation As String 
    Dim projectSearchRange As Range 
    Dim LastRow As Integer 
    Dim NewWorkbook As Workbook 
    Dim copy_range As Range 


    'set search value (porject key - unique) 
    projectref = cmb_Project.Value 

    Application.ScreenUpdating = False 
    Workbooks("Project tracker spreadsheet VBA").Activate 

    Dim wbSource As Excel.Workbook 
    Set wbSource = Workbooks("Project tracker spreadsheet VBA") 

    'find the project reference in the tracking spreadsheet 
    With Sheets("Project Tracking") 
     Set projectSearchRange = .Range("A:A").Find(projectref, , xlValues, xlWhole) 
     If Not projectSearchRange Is Nothing Then '<-- verify that find was successful 
      LastRow = projectSearchRange.Row 
      'file directory to save the new workbook in 
      savelocation = .Cells(LastRow, 5).Value 
     Else '<-- find was unsuccessful 
      MsgBox "Unable to find " & projectref 
      Exit Sub 
     End If 
    End With 

    Dim wsMilestoneTempate As Excel.Worksheet 
    Set wsMilestoneTempate = wbSource.Worksheets("Milestone_Template") 

    Set copy_range = wsMilestoneTempate.Range(wsMilestoneTempate.Cells(LastRow, 11), wsMilestoneTempate.Cells(LastRow, 34)) 
    copy_range.Copy 
    ''''Worksheets("Milestone_Template").Range(copy_range).Copy 'application defined or object defined error occurs here 
    Worksheets("Project Tracking").Range("A7:X7").PasteSpecial Paste:=xlPasteValues 

    Application.CutCopyMode = False 
End Sub