Как убить linux spawnProcess, когда основной процесс внезапно умирает?

Question

Я столкнулся с проблемой с моим приложением и spawnProcess. Если основное приложение по какой-либо причине погибает/убито, то, по-видимому, живут процессы, и я не могу связаться с ними, если я не использую терминал, чтобы убить их через их PID. Моя цель состоит в том, что если основное приложение умирает, тогда порожденные процессы также должны быть убиты.

Мой код как этот

auto appPid = spawnProcess("path/to/process"); 
scope(exit){ auto exitcode = wait(appPid); 
stderr.writeln(...);} 

И если я использую тот же подход, когда основной процесс умирает, используя wait(thisProcessID) я получаю сообщение об ошибке. Msgstr "Нет совпадений перегрузки". Любые идеи, как решить эту проблему?

Answer 1

Вот код, который будет работать в Linux. Он не имеет всех функций spwnProcess stdlib, он просто показывает основные основы, но расширение его здесь не сложно, если вам нужно больше.

import core.sys.posix.unistd; 

version(linux) { 
     // this function is Linux-specific 
     import core.stdc.config; 
     import core.sys.posix.signal; 
     // we can tell the kernel to send our child process a signal 
     // when the parent dies... 
     extern(C) int prctl(int, c_ulong, c_ulong, c_ulong, c_ulong); 
     // the constant I pulled out of the C headers 
     enum PR_SET_PDEATHSIG = 1; 
} 

pid_t mySpawnProcess(string process) { 
     if(auto pid = fork()) { 
       // this branch is the parent, it can return the child pid 
       // you can: 
       // import core.sys.posix.sys.wait; 
       // waitpid(this_ret_value, &status, 0); 
       // if you want the parent to wait for the child to die 
       return pid; 
     } else { 
       // child 

       // first, tell it to terminate when the parent dies 
       prctl(PR_SET_PDEATHSIG, SIGTERM, 0, 0, 0); 

       // then, exec our process 
       char*[2] args; 
       char[255] buffer; 
       // gotta copy the string into another buffer 
       // so we zero terminate it and have a C style char**... 
       buffer[0 .. process.length] = process[]; 
       buffer[process.length] = 0; 
       args[0] = buffer.ptr; 

       // then call exec to run the new program 
       execve(args[0], args.ptr, null); 
       assert(0); // never reached 
     } 
} 

void main() { 
     mySpawnProcess("/usr/bin/cat"); 
     // parent process sleeps for one second, then exits 
     usleep(1_000_000); 
} 

Поэтому необходимо использовать функции нижнего уровня, но у Linux есть функция, которая делает то, что вам нужно.

Конечно, так как он посылает сигнал, ваш ребенок может хотеть, чтобы справиться с этим, чтобы закрыть более изящно, чем прекращение по умолчанию, но попробовать эту программу и запустить ps, пока он спит, чтобы увидеть cat работает, обратите внимание на то кошка умирает, когда родительский выход.