Сравнение данных из столбца A и столбца B Как только

Question

Я сейчас в процессе анализа данных из Excel и хотел бы сделать сравнения данных в столбце A и столбце B, идентифицируя повторяющиеся данные. Я использую следующий код:

Sub Find_Matches() 
Dim CompareRange As Variant, x As Variant, y As Variant 
Set CompareRange = Range("c2", Range("c2").End(xlUp)) 

For Each x In Selection 
    For Each y In CompareRange 
     If x = y Then x.Offset(0, 1) = x 
    Next y 
Next x 
End Sub 

Этот код был взят из MSDN, поэтому, если он находит соответствие в колонке C против колонка А, он будет отображать совпадающее число в колонке B. По большей части это делает то, что мне нужно. Однако я хочу изменить этот код, чтобы он соответствовал только одному числу в списке.

Пример того, что в данный момент делает код:

A2 B2 C2 
1 1 1 
1 1 2 
1 1 3 

Так, по существу, так как число 1 появляется один раз в колонке C, Колонка А продолжает находить совпадения.

Что я хотел бы это сделать, это:

A2 B2 C2 
1 1 1 
1  2 
1  3 

Так, так как число 1 появляется только в колонке C один раз, он должен быть согласован только один раз против чисел в колонке А.

I Предполагая, что это, вероятно, что-то простое, но я не могу определить логику. Может ли кто-нибудь указать мне в правильном направлении, пожалуйста?

Answer 1

Тестирование дубликатов может быть простым или сложным в зависимости от того, насколько быстро вы хотите, чтобы ваша процедура была и насколько велики наборы данных.

Я лично одобряю объект Collection, потому что он имеет уникальный ключ и тестирование на наличие этого ключа очень быстро, особенно если набор данных большой. Уникальный тест выполняется, если код вызывает ошибку при опросе Collection для конкретного ключа. Некоторые из них философски возражают против тестирования ошибок - я должен сказать, что я один, поэтому я фактически предпочитаю объект Dictionary, но для задачи это обыденное, я не буду выполнять шаги, чтобы ссылаться на это.

Вы также увидите, что приведенный ниже код работает с массивами, а не с ячейками на самом листе - опять же, это вопрос личного вкуса, потому что он быстрее.

Const SOURCE_COL As String = "A" 
Const SOURCE_START_ROW As Long = 2 
Const COMPARE_COL As String = "C" 
Const COMPARE_START_ROW As Long = 2 
Const OUTPUT_COL As String = "B" 

Dim ws As Worksheet 
Dim sourceValues As Variant 
Dim compareValues As Variant 
Dim outputValues() As Variant 
Dim sourceIndex As Long 
Dim compareIndex As Long 
Dim uniques As Collection 
Dim val As Variant 
Dim key As String 
Dim exists As Variant 

Set ws = ThisWorkbook.Worksheets("Sheet1") 
sourceValues = ws.Range(ws.Cells(SOURCE_START_ROW, SOURCE_COL), _ 
         ws.Cells(Rows.Count, SOURCE_COL).End(xlUp)).Value2 

compareValues = ws.Range(ws.Cells(COMPARE_START_ROW, COMPARE_COL), _ 
         ws.Cells(Rows.Count, COMPARE_COL).End(xlUp)).Value2 

Set uniques = New Collection 
ReDim outputValues(1 To UBound(sourceValues, 1), 1 To 1) 

For sourceIndex = 1 To UBound(sourceValues, 1) 

    val = sourceValues(sourceIndex, 1) 
    key = CStr(val) 
    exists = Empty 
    On Error Resume Next 
    exists = uniques(key) 
    On Error GoTo 0 

    If IsEmpty(exists) Then 

     For compareIndex = 1 To UBound(compareValues, 1) 
      If val = compareValues(compareIndex, 1) Then 
       outputValues(sourceIndex, 1) = val 
       uniques.Add val, key 
       Exit For 
      End If 
     Next 

    End If 

Next 

ws.Cells(SOURCE_START_ROW, OUTPUT_COL).Resize(UBound(outputValues, 1)).Value = outputValues