Excel VBA проверяет, установлен ли именованный диапазон

Question

Я пытаюсь определить, был ли именованный диапазон установлен через VBA. Именованный диапазон называется LoadedToken и по существу загружается, когда пользователь нажимает на определенную кнопку. Я использую это как доказательство того, что инициализация состоялась.

У меня есть функция, чтобы проверить, если это имело место:

Function ToolIsEnabled() 

    ' We check if the R2A add-in has been loaded by detecting the named range 
    If ActiveWorkbook.Names("LoadedToken") Is Nothing Then 
     ToolIsEnabled = False 
    Else 
     ToolIsEnabled = True 
    End If 

End Function 

и я получаю сообщение об ошибке приложения. Конечно, VBA неверен. Однако как я могу это сделать ?!

Answer 1

Sub Test() 
    Debug.Print IsNamedRange("Bumsti") 
End Sub 

Function IsNamedRange(RName As String) As Boolean 
Dim N As Name 

    IsNamedRange = False 
    For Each N In ActiveWorkbook.Names 
     If N.Name = RName Then 
      IsNamedRange = True 
      Exit For 
     End If 
    Next 
End Function 

Использование в контексте ОП может быть

' ... 
If IsNamedRange("LoadedToken") Then 
    ' ... 
End If 
' ... 

или - если программа конкретных Bool необходимо установить

' ... 
Dim IsTokenLoaded as Boolean 
IsTokenLoaded = IsNamedRange("LoadedToken") 
' ... 

Both constr ucts делают это довольно ясно в исходном коде, к чему вы стремитесь.

Answer 2

Вы можете добиться этого с помощью обработки ошибок:

Function ToolIsEnabled() As Boolean 
    Dim rng As Range 

    On Error Resume Next 
    Set rng = ActiveWorkbook.Range("LoadedToken") 
    On Error GoTo 0 

    ToolIsEnabled = Not rng is Nothing 

End Function 

Answer 3

Это будет проверяться либо в ThisWorkbook, либо в названной книге, и возвращает TRUE/FALSE.

Sub Test() 

    MsgBox NamedRangeExists("SomeName") 
    MsgBox NamedRangeExists("SomeOtherName", Workbooks("Book1.xls")) 

End Sub 

Public Function NamedRangeExists(sName As String, Optional Book As Workbook) As Boolean 

    On Error Resume Next 

     If Book Is Nothing Then 
      Set Book = ThisWorkbook 
     End If 

     NamedRangeExists = Book.Names(sName).Index <> (Err.Number = 0) 

    On Error GoTo 0 

End Function 

Edit: Сокращенный вариант, если он только будет выглядеть в ThisWorkbook:

Public Function NamedRangeExists(sName As String) As Boolean 

    On Error Resume Next 

     NamedRangeExists = ThisWorkbook.Names(sName).Index <> (Err.Number = 0) 

    On Error GoTo 0 

End Function 

Answer 4

Для ActiveWorkbook, вы можете также вызвать функцию старого XLM ИМЕНА():

Function IsNameInActiveWorkbook(sName As String) As Boolean 
    IsNameInActiveWorkbook = Not IsError(Application.ExecuteExcel4Macro("MATCH(""" & sName & """,NAMES(),0)")) 
End Function