Как применить шаблоны к каждому выбранному узлу в каждом из них?

Question

Я знаю, что мне что-то не хватает. В приведенном ниже преобразовании XSLT фактический результат не соответствует желаемому результату.

Внутри for-each, я хочу применить шаблон match="track" к каждому выбранному элементу track. Если я правильно понял XSLT, с текущей настройкой только дочерние узлы каждого выбранного элемента track сопоставляются с шаблонами, а не с самими элементами track.

Как я могу сделать элементы track пройти через шаблон по своему желанию? Нужно ли мне пересмотреть весь мой подход?

Примечание: преобразование выполняется с использованием PHP. Объявления XML для краткости опущены.

XML документа:

<album> 
    <title>Grave Dancers Union</title> 
    <track id="shove">Somebody To Shove</track> 
    <track id="gold">Black Gold</track> 
    <track id="train">Runaway Train</track> 
    <producer>Michael Beinhorn</producer> 
</album> 

XSL Stylesheet:

<xsl:stylesheet version="1.1" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/album"> 
     <ol> 
      <xsl:for-each select="track"> 
       <li><xsl:apply-templates/></li> 
      </xsl:for-each> 
     </ol> 
    </xsl:template> 

    <xsl:template match="track"> 
     <a href="{@id}"><xsl:apply-templates/></a> 
    </xsl:template> 
</xsl:stylesheet> 

Результат:

<ol> 
    <li>Somebody To Shove</li> 
    <li>Black Gold</li> 
    <li>Runaway Train</li> 
</ol> 

Желаемый результат:

<ol> 
    <li><a href="shove">Somebody To Shove</a></li> 
    <li><a href="gold">Black Gold</a></li> 
    <li><a href="train">Runaway Train</a></li> 
</ol> 

Answer 1

Я согласен с 'ndim', что вы, вероятно, должны перестроить свой XSLT, чтобы покончить с циклом xsl: for-each.

В качестве альтернативы, вы можете изменить XSL: применить-шаблоны для выбора текущего узла дорожки в пределах XSL: для-каждого

<xsl:for-each select="track"> 
    <li> 
     <xsl:apply-templates select="." /> 
    </li> 
</xsl:for-each> 

Сохраняя XSL: за-каждый будет, по крайней мере, позволит вам сортируйте треки в другом порядке, если хотите.

Answer 2

я реструктурировать это немного (если не нужен сортировки for-each подход делает возможным):

<xsl:template match="/album"> 
    <ol> 
    <xsl:apply-templates select="track"/> 
    </ol> 
</xsl:template> 

<xsl:template match="track"> 
    <li><a href="{@id}"><xsl:apply-templates/></a></li> 
<xsl:template> 

Это выглядит короче и ближе к делу , ИМХО.

Я думаю, ваш

<xsl:for-each select="track"> 
     <li><xsl:apply-templates/></li> 
    </xsl:for-each> 

проходит через все элементы дорожки с for-each, а затем применяет правила по умолчанию для его потомков. Таким образом, содержимое for-each имеет тот же контекстный узел, что и шаблон match="track", и поэтому шаблон match="track" никогда не совпадает.

Если вы действительно хотите использовать for-each таким образом, вам нужно будет изменить одно из следующих двух вещей в вашем подходе:

1. Добавьте атрибут name="track" в match="track" шаблон, а затем использовать <xsl:call-template/> изнутри for-each (моя идея, и хуже, чем Tim C)
2. Использование решения Tim C с использованием <xsl:apply-templates select="."/>. Преимущество этого заключается в том, чтобы избежать именования и сохранения возможности сортировки дорожек.