Лучший способ закодировать это, строка для отображения преобразования в Groovy

Question

У меня есть строка, как

def data = "session=234567893egshdjchasd&userId=12345673456&timeOut=1800000" 

Я хочу, чтобы преобразовать его в карту

["session", 234567893egshdjchasd] 
["userId", 12345673456] 
["timeout", 1800000] 

Это текущий путь я делаю it,

def map = [:] 

data.splitEachLine("&"){ 

    it.each{ x -> 

    def object = x.split("=") 
    map.put(object[0], object[1]) 

    } 

} 

Это работает, но есть ли более эффективный способ?

Answer 1

Я не знаю, думаю, что это будет работать быстрее, но это делает предложить себя с точки зрения синтаксической скупости:

def data = 'session=234567893egshdjchasd&userId=12345673456&timeOut=1800000' 
def result = data.split('&').inject([:]) { map, token -> 
    token.split('=').with { map[it[0]] = it[1] } 
    map 
} 

Лично мне ответ Дона для читаемости и ремонтопригодность, но в зависимости от контекста, это может быть целесообразным.

Редактировать: Это фактически переформатированный однострочный.

Answer 2

Я не знаю, если это более эффективно, но на моих глазах, это немного проще (YMMV)

def data = "session=234567893egshdjchasd&userId=12345673456&timeOut=1800000" 
def map = [:] 

data.split("&").each {param -> 
    def nameAndValue = param.split("=") 
    map[nameAndValue[0]] = nameAndValue[1] 
} 

Answer 3

Если вы ищете эффективные регулярные выражения, где это в:

def data = "session=234567893egshdjchasd&userId=12345673456&timeOut=1800000" 
def map = [:] 
data.findAll(/([^&=]+)=([^&]+)/) { full, name, value -> map[name] = value } 

println map 

принтами:

[session:234567893egshdjchasd, userId:12345673456, timeOut:1800000] 

Если вы не знакомы с регулярными выражениями, это может выглядеть немного чужой, но это действительно не так сложно. У него просто две (группы), первая группа - любой символ, но «&» или «=». Вторая группа - любой символ, кроме «=». Группы захвата расположены по обе стороны от «=».

Answer 4

Если в контроллере Grails, то это просто и красиво:

GrailsParameterMap map = new GrailsParameterMap(request) 

http://grails.org/doc/latest/api/org/codehaus/groovy/grails/web/servlet/mvc/GrailsParameterMap.html

Answer 5

Если вы используете Grails, лучший способ я нахожу WebUtils функция fromQueryString.

https://grails.github.io/grails-doc/2.0.x/api/org/codehaus/groovy/grails/web/util/WebUtils.html

Answer 6

Вот мои усилия, который инициализирует и заполняет карту в один присест, и избегает метод INJECT который я лично найти трудно следовать: -

def map = data.split('&').collectEntries { 
     def kvp = it.split('=').collect { string -> 
      string = string.trim() 
      return string 
    } 
    [(kvp[0]): kvp.size() > 1 ? kvp[1] ?: '' : ''] 
    // the null check is almost certainly overkill so you could use :- 
    // [(kvp[0]): kvp.size() > 1 ? kvp[1] : ''] 
    // this just checks that a value was found and inserts an empty string instead of null 
} 

Answer 7

После некоторых поисков, «collectEntries() "- это волшебная вещь для использования, она создает элемент карты. Работайте так же, как «collect()», который создает список.Поэтому, учитывая

def params = "a1=b1&a2=b2&a3&a4=&a5=x=y" 

один-лайнер

map = params.tokenize("&").collectEntries{ 
      it.split("=",2).with{ 
       [ (it[0]): (it.size()<2) ? null : it[1] ?: null ] 
      } 
     } 

, который создает

map = [a1:b1, a2:b2, a3:null, a4:null, a5:x=y] 

В зависимости, как вы хотите обрабатывать случаи "a3" и "a4 =" Вы можете также использовать немного более короткая версия

... 
[ (it[0]): (it.size()<2) ? null : it[1] ] 
... 

, а затем вы получите это:

map = [a1:b1, a2:b2, a3:null, a4:, a5:x=y]