VBA - Оценить условия как строки

Question

Я столкнулся с очень странным сценарием. В функции я получаю строку условия для оценки.

Э.Г.

(a>b and (b=2 or c!=3)) 

где а, Ь и с являются мои имена переменных.

Я пробовал и много искал, но не получил ничего значимого.

Так что мой вопрос: возможно ли оценить такую ​​строку? Если да, пожалуйста, предоставьте мне некоторый намек на это.

Answer 1

Альтернативный способ, добавить ссылку на Microsoft Script Control

Dim vx As MSScriptControl.ScriptControl 
Set vx = New MSScriptControl.ScriptControl 

a = 100 
b = 200 
c = 300 
Cond = "(a>b and (b=2 or c<>3))" 

With vx 
    .Language = "VBScript" 
    .AddCode "function stub(a,b,c): stub=" & Cond & ": end function" 

    result = .Run("stub", a, b, c) 
End With 

MsgBox result 

Примечание вам нужно будет заменить = с <> как первый недействителен в VB * (и и/или нет t valid in jScript)

Answer 2

Вот правильный ответ на ваш вопрос, а не только комментарий.

Вам нужно:

• Установить ссылку на Microsoft Visual Basic for Applications Extensibility x.x (Tools/References) в VBIDE.
• Доверьте доступ к объектной модели проекта VBA (используйте Google, чтобы узнать, как это сделать для вашей версии Excel).
• Run initValues() затем вызвать getConstantValue("(a>b and (b=2 or c<>3))")

Код:

Option Explicit 

Dim a As Long 
Dim b As Long 
Dim c As Long 

Sub initValues() 
    a = 3 
    b = 2 
    c = 4 
End Sub 

Function getConstantValue(constStr As String) As Variant 

    Dim oMod As VBIDE.CodeModule 
    Dim i As Long, _ 
     num As Long 

    Set oMod = ThisWorkbook.VBProject.VBComponents("Module1").CodeModule 

    For i = 1 To oMod.CountOfLines 
     If oMod.Lines(i, 1) = "Function tempGetConstValue() As Variant" Then 
      num = i + 1 
      Exit For 
     End If 
    Next i 

    oMod.InsertLines num, "tempGetConstValue = " & constStr 

    getConstantValue = Application.Run("tempGetConstValue") 

    oMod.DeleteLines num 

End Function 

Function tempGetConstValue() As Variant 
End Function