Как программно отклонить (повесить) входящий звонок на Android в Delphi?

Question

решение Java, это не проблема:

public boolean killCall(Context context) { 
    try { 
     // Get the boring old TelephonyManager 
     TelephonyManager telephonyManager = 
       (TelephonyManager) context.getSystemService(Context.TELEPHONY_SERVICE); 

     // Get the getITelephony() method 
     Class classTelephony = Class.forName(telephonyManager.getClass().getName()); 
     Method methodGetITelephony = classTelephony.getDeclaredMethod("getITelephony"); 

     // Ignore that the method is supposed to be private 
     methodGetITelephony.setAccessible(true); 

     // Invoke getITelephony() to get the ITelephony interface 
     Object telephonyInterface = methodGetITelephony.invoke(telephonyManager); 

     // Get the endCall method from ITelephony 
     Class telephonyInterfaceClass = 
       Class.forName(telephonyInterface.getClass().getName()); 
     Method methodEndCall = telephonyInterfaceClass.getDeclaredMethod("endCall"); 

     // Invoke endCall() 
     methodEndCall.invoke(telephonyInterface); 

    } catch (Exception ex) { // Many things can go wrong with reflection calls 
     Log.d(TAG,"PhoneStateReceiver **" + ex.toString()); 
     return false; 
    } 
    return true; 
} 

Но как сделать такое же решение в Delphi?

К сожалению, я не нашёл ни одного руководства, чтобы решить эту проблему.

Answer 1

К сожалению, то, что вы просите в настоящее время не представляется возможным в Delphi кода непосредственно, из-за известной ошибки в рамках Android Bridge в Delphi:

QC#120233 Android Jlang_Class interface is missing 19 methods

QP #RSP-12686 Android Jlang_Class interface is missing 19 methods

getDeclaredMethod() является одним из отсутствующие методы, и без него вы не сможете получить доступ к интерфейсу ITelephony. Таким образом, вы просто должны написать, что часть вашего приложения в Java коде, обернуть его внутри .jar файл и импортировать в код Delphi в качестве внешнего API, в документации Embarcadero по:

Using a Custom Set of Java Libraries In Your RAD Studio Android Apps

Update : в Сиэтле, большинство отсутствующих методов теперь добавлено к Jlang_Class. Однако getDeclaredMethod() не один из них, но, к счастью getDeclaredMethods() был добавлен, так что вы должны быть в состоянии написать небольшую обертку для этого, например:

function getdeclaredMethod(Cls: Jlang_Class; const Name: JString): JMethod; 
var 
    Arr: TJavaObjectArray<JMethod>; 
    Meth: JMethod; 
    I: Integer; 
begin 
    Result := nil; 
    Arr := Cls.getDeclaredMethods; 
    for I := 0 to Arr.Length-1 do 
    begin 
    Meth := Arr.Items[I]; 
    if Meth.getName.compareTo(Name) = 0 then 
    begin 
     Result := Method; 
     Exit; 
    end; 
    end; 
    raise Exception.CreateFmt('method not found: %s', [Name]); 
end; 

И тогда вы можете сделать это:

function killCall(context: JContext): Boolean; 
var 
    obj: JObject; 
    telephonyManager: JTelephonyManager; 
    classTelephony: Jlang_Class; 
    methodGetITelephony: JMethod; 
    telephonyInterface: JObject; 
    telephonyInterfaceClass: Jlang_Class; 
    methodEndCall: JMethod; 
begin 
    try 
    // Get the boring old TelephonyManager 
    obj := context.getSystemService(TJContext.JavaClass.TELEPHONY_SERVICE); 
    telephonyManager := TJTelephonyManager.Wrap((obj as ILocalObject).GetObjectID); 

    // Get the getITelephony() method 
    classTelephony := TJlang_Class.JavaClass.forName(telephonyManager.getClass.getName); 
    methodGetITelephony := getDeclaredMethod(classTelephony, StringToJString('getITelephony')); 

    // Ignore that the method is supposed to be private 
    methodGetITelephony.setAccessible(True); 

    // Invoke getITelephony() to get the ITelephony interface 
    telephonyInterface := methodGetITelephony.invoke(telephonyManager); 

    // Get the endCall method from ITelephony 
    telephonyInterfaceClass := TJlang_Class.JavaClass.forName(telephonyInterface.getClass.getName); 
    methodEndCall := getDeclaredMethod(telephonyInterfaceClass, StringToJString('endCall')); 

    // Invoke endCall() 
    methodEndCall.invoke(telephonyInterface); 

    Result := True; 
    except 
    on E: Exception do // Many things can go wrong with reflection calls 
    begin 
     // 
     Result := False; 
    end; 
    end; 
end;