Как заблокировать ячейку на основе значения другой ячейки и выполнить проверку данных

Question

Я очень новичок в коде VBA. Теперь мне было поручено выполнить задачу, которая проверяет данные на листах excel.

Например, в моем Столбец У меня есть раскрывающееся меню, которое позволяет пользователю делать выбор между «Да» или «Нет».

• Если пользователь выбрал «Да», ячейки в столбце B и столбце C будут отмечены как обязательные и не могут быть пустыми. Я хочу поставить на это ошибку проверки.

  **Example 1: If A1 and A30 == YES** 
  

  • B1 и C1, B30 и C30 являются обязательными

  • заполнит цвет обязательных элементов и удалить цвет заливки, когда клетки имеют ценность уже

  • кинуть ошибка проверки, когда эти ячейки пусты и если превышает количество требуемых символов.

    Пример 2: Если A99 == НЕТ

  • B99 будут заблокированы, и пользователь не будет иметь возможность вводить данные на этой ячейке. Возможно, что мы можем добавить значение ячейки как «NA», чтобы избежать путаницы

я смог захватить это с помощью проверки данных и условного форматирования. Тем не менее, я не могу выполнять заблокированные функции, так как в ходе исследования мне нужен код VBA для этого.

Answer 1

Что-то вроде этого должно работать.

Поместите его в модуль кода для листа, к которому вы хотите применить его.

Private Sub worksheet_change(ByVal target As Range) 

    ''''' CHECK IF THE CHANGED CELL IS IN RANGE A1:A99 (OR ANY OTHER RANGE YOU DEFINE) 
    If Not Intersect(target, Range("A1:A99")) Is Nothing Then 

     ''''' UNPROTECT THE SHEET 
     ActiveSheet.Unprotect 

     ''''' IF THE CELL CHANGED IS NOW 'YES' 
     If target = "Yes" Then 

      ''''' WE DEFINE HOW MANY COLUMNS TO MOVE ACROSS FROM THE CELL THAT CHANGED AND DO THE ACTIONS IN THE CODE BELOW 
      ''''' SO IN THIS EXAMPLE WE'RE MOVING ACROSS 1 CELL TO B1 AND THEN 2 CELLS TO C1 
      ''''' SO TO GET TO AA1 AND AB2 WE'D DO i = 26 to 27 
      ''''' IF WE WANTED TO ACCESS AA1 ALL THE WAY THROUGH TO AZ1 WE'D DO i = 26 to 51 
      For i = 1 To 2 

       ''''' MOVE ACROSS i NUMBER OF CELLS FROM THE CELL THAT CHANGED 
       With target.Offset(0, i) 

        ''''' UNLOCK THE CELL 
        .Locked = False 

        '''''SET THE CONDITIONAL FORMATTING 
        .FormatConditions.Add Type:=xlExpression, Formula1:="=ISBLANK(" & target.Offset(0, i).Address & ")" 
        With .FormatConditions(.FormatConditions.Count) 
         .SetFirstPriority 
         .Interior.ColorIndex = 37 
        End With 

       End With 

      ''''' INCREASE i BY 1 AND LOOP TO AFFECT THE NEXT CELL 
      Next i 

     ''''' IF THE CELL CHANGED IS NOW 'NO' 
     ElseIf target = "No" Then 

      ''''' WE DEFINE HOW MANY COLUMNS TO MOVE ACROSS FROM THE CELL THAT CHANGED AND DO THE ACTIONS IN THE CODE BELOW 
      For i = 1 To 2 

       ''''' MOVE ACROSS i NUMBER OF CELLS FROM THE CELL THAT CHANGED 
       With target.Offset(0, i) 

        ''''' SET THE CELL VALUE TO BLANK 
        .Value = "" 

        ''''' LOCK THE CELL 
        .Locked = True 

        ''''' REMOVE THE CONDITIONAL FORMATTING 
        .FormatConditions.Delete 

         ''''' ADD NEW CONDITIONAL FORMATTING HERE IF REQUIRED 

       End With 

      ''''' INCREASE i BY 1 AND LOOP TO AFFECT THE NEXT CELL 
      Next i 

     End If 

     '''''PROTECT THE SHEET 
     ActiveSheet.Protect 

    End If 

End Sub 

Обязательно установите заперта ложь в столбце А где падение вниз списки или пользователи не смогут изменить выпадающее значение в то время как лист заблокирован.