Обнаружение типа лицензии/типа распространения Visual Studio

Question

Существует множество информации по всей сети о том, как определить тип и тип лицензии Windows, используя PID (который можно найти в разделе реестра HKLM\SYSTEM\Setup\Pid) и ProductID (который можно найти в HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion).

Однако информации о том, каким образом лицензирование используется для установки других продуктов Microsoft, довольно мало.

А именно, что мне нужно определить, какие из них были установлены с использованием лицензии на подписку MSDN и которые были установлены с использованием других типов лицензий.

мне удалось найти некоторую информацию о вкусами офиса путем анализа продукта GUID (находится в отделении Uninstall регистрации):

• Office 2000
• Office XP
• Office 2003
• Office 2007
• Office 2010

Однако все эти статьи различать только между этими типами выпуска:

• 0 Объем лицензии
• 1 Розничная/OEM
• 2 Trial
• 5 Скачать

Кроме того, я не мог найти доступную информацию о других продуктах. А именно, Visual Studio ... (именно это меня интересует больше всего).

Для уточнения: я не нужно получить лицензионный ключ (который я уже нашел несколько способов обнаружения, ища для информации мне нужно), мой интерес только в обнаружении какого рода типа лицензии был использован для установки приложения.

Answer 1

Ok поэтому единственный способ, которым я могу видеть, делать это использовать инструмент, как magicaljellybeans key finder и затем экспортированных ключи от вас MSDN лицензии и сделать сравните.

Из самого программного обеспечения я уверен, что они не идентифицированы как версии MSDN как таковые, но это лицензия, которая активирует их, что определяет, что я уверен, что то, что вы просите, невозможно, поскольку вы описываете он не делает сравнения, что означает, что вам нужен ключ.

Это особенно верно, поскольку некоторые продукты в msdn имеют и используют «розничные версии» программного обеспечения.

Answer 2

http://blogs.msdn.com/b/heaths/archive/2010/05/04/detection-keys-for-net-framework-4-0-and-visual-studio-2010.aspx

Visual Studio 2010 
The detection keys for Visual Studio are used both to detect if the product is installed and what service pack level is installed. As with previous versions, these keys and values are under HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DevDiv\VS\Servicing. 

Key HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DevDiv\VS\Servicing\10.0\$(var.ProductEdition)\$(var.LCID) 
Name Install 
Type REG_DWORD (32-bit integer) 
Data 0x00000001 (1) 
The values for $(var.ProductEdition) include the following table. The for other products, this value corresponds to the ProductEdition property in the Property table of the Windows Installer package for that product. The locale IDs for $(Var.LCID) are listed here. 

Visual Studio 2010 Ultimate  VSTSCore 
Visual Studio 2010 Premium  VSTDCore 
Visual Studio 2010 Professional PROCore 
Visual Studio 2010 Shell (Integrated) IntShell 
For Dev10 we have also added detection values to the edition keys so that you do not have to detect every single language for ever edition. 

Key HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DevDiv\VS\Servicing\10.0\$(var.ProductEdition) 
Name Install 
Type REG_DWORD (32-bit integer) 
Data 0x00000001 (1) 
These registry keys and values are also used to detect the service pack level. Instead of checking for the Name registry value, check the SP registry value. Ignore SPIndex; Microsoft uses this internally. In addition to the registry keys above, we also set a version-dependent registry value listed below. 

Key HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DevDiv\VS\Servicing\10.0 
Name SP 
Type REG_DWORD (32-bit integer) 
Data 0x00000001 (1) 
Keep in mind, however, that as with all shared resources the more shared a resource is the less accurate it may be. This is because there is no version policy for registry values and other resources that do not have versions like text files. If two languages were installed at different servicing pack levels – which is unsupported but possible – the value would be set by the last product to be installed or reinstalled (repaired). 

For more information, see the Visual Studio 2010 detection system requirements. This also includes information to use the CompLocator in your Windows Installer package as an alternative to registry detection. 

http://www.mztools.com/articles/2008/MZ2008003.aspx

To detect which Visual Studio version a (multi-IDE) add-in is running under, you can use the EnvDTE.DTE.RegistryRoot property, which can return the following values: 
For Visual Studio 2005: Software\Microsoft\VisualStudio\8.0 
For Visual Studio 2008: Software\Microsoft\VisualStudio\9.0 
To detect the edition and subedition of the Visual Studio IDE you can use the IVsShell interface, calling its GetProperty method with the Microsoft.VisualStudio.Shell.Interop.__VSSPROPID2.VSSPROPID_SKUEdition and Microsoft.VisualStudio.Shell.Interop.__VSSPROPID2.VSSPROPID_SubSKUEdition values. 

Note: To get a service from an add-in, see HOWTO: Get a Visual Studio service from an add-in; and to know how to reference an assembly from the GAC (such as Microsoft.VisualStudio.Shell.Interop.dll), see HOWTO: Reference a Visual Studio assembly in the GAC from an add-in. 

The returned results are not well documented but some values are provided in the following sample add-in: 

Imports System 
Imports Microsoft.VisualStudio.CommandBars 
Imports Extensibility 
Imports EnvDTE 
Imports System.Runtime.InteropServices 
Imports Microsoft.VisualStudio.Shell.Interop 
Imports System.Windows.Forms 



<ComVisible(True), ComImport(), Guid("6D5140C1-7436-11CE-8034-00AA006009FA"), _ 
InterfaceTypeAttribute(ComInterfaceType.InterfaceIsIUnknown)> _ 
Friend Interface IServiceProvider 
    <PreserveSig()> _ 
    Function QueryService(<InAttribute()> ByRef guidService As Guid, _ 
     <InAttribute()> ByRef riid As Guid, <OutAttribute()> ByRef ppvObject As IntPtr) As Integer 
End Interface 

Public Class Connect 
    Implements IDTExtensibility2 

    Private Enum SKUEdition 
     SKUEdition_None = 0 
     SKUEdition_Express = 500 
     SKUEdition_Standard = &H3E8 
     SKUEdition_Professional = &H7D0 
     SKUEdition_AcademicProfessional = &H834 
     SKUEdition_AcademicStudent = &H834 
     SKUEdition_AcademicStudentMSDNAA = &H898 
     SKUEdition_AcademicEnterprise = &H8FC 
     SKUEdition_Book = &H960 
     SKUEdition_DownloadTrial = &H9C4 
     SKUEdition_Enterprise = &HBB8 
    End Enum 

    Private Enum SubSKUEdition 
     SubSKUEdition_None = &H0 
     SubSKUEdition_VC = &H1 
     SubSKUEdition_VB = &H2 
     SubSKUEdition_CSharp = &H4 
     SubSKUEdition_Architect = &H8 
     SubSKUEdition_IDE = &H10 
     SubSKUEdition_JSharp = &H20 
     SubSKUEdition_Web = &H40 
     SubSKUEdition_TeamEditionDevelopers = &H80 
    End Enum 

    Public Function GetService(ByVal serviceProvider As Object, ByVal type As System.Type) As Object 
     Return GetService(serviceProvider, type.GUID) 
    End Function 

    Public Function GetService(ByVal serviceProvider As Object, ByVal guid As System.Guid) As Object 

     Dim objService As Object = Nothing 
     Dim objIServiceProvider As IServiceProvider 
     Dim objIntPtr As IntPtr 
     Dim hr As Integer 
     Dim objSIDGuid As Guid 
     Dim objIIDGuid As Guid 

     objSIDGuid = guid 
     objIIDGuid = objSIDGuid 
     objIServiceProvider = CType(serviceProvider, IServiceProvider) 

     hr = objIServiceProvider.QueryService(objSIDGuid, objIIDGuid, objIntPtr) 
     If hr <> 0 Then 
     System.Runtime.InteropServices.Marshal.ThrowExceptionForHR(hr) 
     ElseIf Not objIntPtr.Equals(IntPtr.Zero) Then 
     objService = System.Runtime.InteropServices.Marshal.GetObjectForIUnknown(objIntPtr) 
     System.Runtime.InteropServices.Marshal.Release(objIntPtr) 
     End If 

     Return objService 

    End Function 

    Public Sub OnConnection(ByVal Application As Object, ByVal ConnectMode As Extensibility.ext_ConnectMode, _ 
     ByVal AddInInst As Object, ByRef custom As System.Array) _ 
     Implements Extensibility.IDTExtensibility2.OnConnection 

     Dim objDTE As DTE 
     Dim objService As Object 
     Dim objIVsShell As IVsShell 
     Dim objValue As Object = Nothing 
     Dim eSKUEdition As SKUEdition 
     Dim eSubSKUEdition As SubSKUEdition 

     Select Case ConnectMode 

     Case ext_ConnectMode.ext_cm_AfterStartup, ext_ConnectMode.ext_cm_Startup 

      objDTE = DirectCast(Application, DTE) 
      objService = GetService(objDTE, GetType(IVsShell)) 
      objIVsShell = CType(objService, IVsShell) 

      If objIVsShell.GetProperty(__VSSPROPID2.VSSPROPID_SKUEdition, objValue) = 0 Then 
       eSKUEdition = CType(objValue, SKUEdition) 
       MessageBox.Show(eSKUEdition.ToString) 
      End If 

      If objIVsShell.GetProperty(__VSSPROPID2.VSSPROPID_SubSKUEdition, objValue) = 0 Then 
       eSubSKUEdition = CType(objValue, SubSKUEdition) 
       MessageBox.Show(eSubSKUEdition.ToString) 
      End If 

     End Select 

    End Sub 

    Public Sub OnAddInsUpdate(ByRef custom As System.Array) _ 
     Implements Extensibility.IDTExtensibility2.OnAddInsUpdate 

    End Sub 

    Public Sub OnBeginShutdown(ByRef custom As System.Array) _ 
     Implements Extensibility.IDTExtensibility2.OnBeginShutdown 

    End Sub 

    Public Sub OnDisconnection(ByVal RemoveMode As Extensibility.ext_DisconnectMode, _ 
     ByRef custom As System.Array) Implements Extensibility.IDTExtensibility2.OnDisconnection 

    End Sub 

    Public Sub OnStartupComplete(ByRef custom As System.Array) _ 
     Implements Extensibility.IDTExtensibility2.OnStartupComplete 

    End Sub 

End Class 
To detect whether a specific Visual Studio package is installed or not, you can use the IsPackageInstalled method of the IVsShell interface, which receives the Guid of the package. 
Detecting installed Visual Studio Service Packs 

Visual Studio uses the following Windows registry entries to track the installed service packs for the several versions (2005, 2008), editions (Standard, Professional, etc.) and languages (English, Spanish, etc.): 

HKEY_LOCAL_MACHINE\Software\Microsoft\DevDiv\VS\Servicing\<version>\<edition>\<localeId> 

where <version> and <edition> where explained in a previous section of this article and <localeId> is 1033 for English, 3082 for Spanish, etc. 

For example, when Visual Studio 2005 Team Edition for Developers has SP1 installed, the value of the "SP" registry entry of HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\DevDiv\VS\Servicing\8.0\VSTD\1033 is set to 1. 

To know the service at general level (without taking into account the edition and language) you can use the "SP" registry entry under the registry key: 

HKEY_LOCAL_MACHINE\Software\Microsoft\DevDiv\VS\Servicing\<version>