Пролог, отделяющий список от двух других списков

Question

Я пытаюсь прочитать список, проверить элемент, если элемент находится в КБ, что-то сделать, и добавить его в другой список, если его нет в КБ затем добавьте его в другой, третий список.

Я продолжаю думать о процедурной логике и не могу по-настоящему обвести ее вокруг себя. Это то, что я имеет смысл для меня, - но это не работает ...

//KB 
r([a|X],Y,[gone|X]). 
r([c|X],Y,[gone|X]). 
r([b|X],Y,[known|X]). 
r([d|X],Y,[known2|X]). 

simplify([X|List],[X|NW],Result) :- 
    r(List,Nw,NewList), 
    !, 
    simplify2(NewList,Nw,Result). 

simplify2([W|Words],Nw,[W|NewWords]) :- 
    simplify2(Words,Nw,NewWords). 

simplify2([],[],[]). 

Запрос:

- упростить ([а, Ь, с, d, е, е], X , Y).

Я хочу:

X = [e,f] 
Y = [gone,known,gone,known2] 

но выше дает X = [a|mem_address] и Y = [d,e].

Answer 1

Ну, сначала вам нужно собрать данные из КБ (фактически, общий термин - База данных), используя setof. И тогда это просто:

r([a|X],Y,[gone|X]). 
r([c|X],Y,[gone|X]). 
r([b|X],Y,[known|X]). 
r([d|X],Y,[known2|X]). 

kb(L) :- setof((A,B), r([A|_],_,[B|_]), L). 

simplify([], [], []). 
simplify([H|T], T1, [H2|T2]) :- 
    kb(L), 
    member((H,H2), L), 
    simplify(T, T1, T2). 

simplify([H|T], [H|T1], T2) :- 
    simplify(T, T1, T2). 

Answer 2

Давайте сначала исправить синтаксис:

• Rest-оф-лайн комментарий в Прологе начинается с % не //.
• Удалить второй аргумент из r/3; это не имеет целью.
• MW ->Mw в simplify/3.
• Вставка пробелов между аргументами (не синтаксически некорректная, но немного сложная для чтения).

Теперь давайте удалим некоторые увольнения:

• В r/2 вы на самом деле не нужны список хвосты.
• Кроме того, нам не нужен список, чтобы указать, что какой-то термин «известен» или «ушел».
• simplify/3 и simplify2/3 могут быть объединены в один и тот же предикат.

Теперь давайте добавим некоторые новые вещи:

• Объявить r/2 в динамический. Это позволяет изменять KB с использованием assert/1 и retract/1.
• Использовать согласованное присвоение имен для переменных. Например, H для заголовка списка, T для списка tail и L для (полного) списка.

Мы получаем следующее:

:- dynamic(r/2). 

r(a, gone). 
r(c, gone). 
r(b, known). 
r(d, known2). 

simplify([], [], []). 
simplify([H|T1], L2, L3):- 
    ( r(H, Status) 
    -> L2 = T2, 
     L3 = [Status|T3] 
    ; L2 = [H|T2], 
     L3 = T3 
), 
    simplify(T1, T2, T3). 

С желаемого поведения:

?- simplify([a,b,c,d,e,f],X,Y). 
X = [e, f], 
Y = [gone, known, gone, known2]. 

Обратите внимание, как в приведенном выше я выполнил следующие действия:

1. я стараюсь для получения синтаксически допустимого Prolog.
2. Как только программа имеет действительный синтаксис, я пытаюсь упростить ее, сохраняя стабильное/неповрежденное поведение.
3. Только, когда код является синтаксически действительным и упрощенным, я начинаю изменять его, чтобы достичь намеченного поведения.

Edit: Благодаря false для указания на не-пристальном поведения. Программа была отредактирована соответствующим образом.