Как обмануть проверку прототипа?

Question

Хотите написать простую оболочку для некоторого внешнего модуля perl. Упрощенный пример:

use 5.014; 
use warnings; 

#foreign package 
package Some { 
    sub func { 
     my($x,$y) = @_; 
     return $x.$y; 
    } 
}; 

#my own packages 
package My { 
    #use Some(); 
    sub func { Some::func(@_); } 
} 

package main { 
    #use My; 
    say My::func("res","ult"); 
} 

Это хорошо работает и печатает result.

Но теперь я встречаю модуль, который использует прототипы, например. Вышеприведенный пример выглядит как:

package Some { 
    sub func($$) {  # <-- prototype check 
     my($x,$y) = @_; 
     return $x.$y; 
    } 
}; 

При попытке использовать My обертку пакет - он говорит:

Not enough arguments for Some::func at ppp line 16, near "@_)" 

ли возможно «обмануть» на проверку прототипа или я должен написать свою обертку, как это?

sub func { Some::func($_[0],$_[1]); } 

или даже

sub func($$) { Some::func($_[0],$_[1]); } 

Answer 1

&Some::func(@_); # Bypass prototype check. 

Есть и другие варианты.

(\&Some::func)->(@_); # Call via a reference. 
&Some::func;   # Don't create a new @_. 
goto &Some::func;  # Don't create a new @_, and remove current call frame from stack. 

Метод вызова всегда игнорирует прототипы.