«Приостановка» Нить со свойством

Question

У меня есть объект TThread и хочу, чтобы иметь возможность запускать/останавливать поток на главной форме программы с помощью кнопки. Я искал способы сделать это, и до сих пор у меня есть следующие идеи:

1. Завершить и освободить поток, когда пользователь нажимает кнопку «Стоп» и создает новый при нажатии кнопки «Пуск».
2. Используйте sleep, чтобы задержать поток (я не хочу этого делать)
3. Имейте свойство, которое является логическим, чтобы определить, приостановлен ли поток или нет. Код в Execute будет выполняться только в том случае, если это логическое значение false.

Я склоняюсь к # 3. Устанавливает ли логическое свойство объекта TThread из основной формы потокобезопасным?

Какой из этих вариантов, или какой-либо лучшей альтернативы, я должен идти с? Это первый раз, когда я использую нитки, поэтому любая помощь оценивается.

Answer 1

1.Terminate и Free the thread, когда пользователь нажимает кнопку остановки и создает новую, когда они нажимают кнопку запуска.

Это, безусловно, вариант, если накладные расходы минимальны.

3. Имеет свойство, которое является логическим, чтобы определить, приостановлена ​​ли нить или нет. Код в Execute будет выполняться только в том случае, если это логическое значение false.

Вы могли бы это сделать, но вам нужно будет регулярно проверять это булево, и если он установлен, введите цикл ожидания до тех пор, пока он не будет очищен или поток не будет завершен.

Будет ли установка булевого свойства на объект TThread из основной формы быть потокобезопасной?

Это как потокобезопасная как вызов TThread.Terminate(), который просто устанавливает логическое TThread.Terminated свойства.

Каким из этих вариантов, или любой лучшей альтернативой, я должен пойти?

Я использую опцию # 4 - используя сигнальные события вместо булевых. Например:

type 
    TMyThread = class(TThread) 
    private 
    FRunEvent, FTermEvent: TEvent; 
    FWaitEvents: THandleObjectArray; 
    procedure CheckPause; 
    protected 
    procedure Execute; override; 
    procedure TerminatedSet; override; 
    public 
    constructor Create; reintroduce; 
    destructor Destroy; override; 
    procedure Pause; 
    procedure Unpause; 
    end; 

constructor TMyThread.Create; 
begin 
    inherited Create(False); 

    FRunEvent := TEvent.Create(nil, True, True, ''); 
    FTermEvent := TEvent.Create(nil, True, False, ''); 

    SetLength(FWaitEvents, 2); 
    FWaitEvents[0] := FRunEvent; 
    FWaitEvents[1] := FTermEvent; 
end; 

destructor TMyThread.Destroy; 
begin 
    FRunEvent.Free; 
    FTermEvent.Free; 
    inherited; 
end; 

procedure TMyThread.Execute; 
begin 
    while not Terminated do 
    begin 
    // do some work... 
    CheckPause; 
    // do some more work... 
    CheckPause; 
    // do some more work... 
    CheckPause; 
    //... 
    end; 
end; 

procedure TMyThread.TerminatedSet; 
begin 
    FTermEvent.SetEvent; 
end; 

procedure TMyThread.CheckPause; 
var 
    SignaledEvent: THandleObject; 
begin 
    while not Terminated do 
    begin 
    case TEvent.WaitForMultiple(FWaitEvents, INFINITE, False, SignaledEvent) of 
     wrSignaled: begin 
     if SignaledEvent = FRunEvent then Exit; 
     Break; 
     end; 
     wrIOCompletion: begin 
     // retry 
     end; 
     wrError: begin 
     RaiseLastOSError; 
    end; 
    end; 
    SysUtils.Abort; 
end; 

procedure TMyThread.Pause; 
begin 
    FRunEvent.ResetEvent; 
end; 

procedure TMyThread.Unpause; 
begin 
    FRunEvent.SetEvent; 
end; 

Answer 2

Заканчивать вики для Delphi на запуск и остановка темы здесь: http://docwiki.embarcadero.com/RADStudio/Berlin/en/Starting_and_Stopping_Threads

Это применимо еще в Delphi 7. Это может быть применимо дальше назад, но я не могу подтвердить более ранние версии.