Как использовать XSLT для создания различных значений

Question

У меня есть XML, как это:

<items> 
    <item> 
    <products> 
     <product>laptop</product> 
     <product>charger</product> 
    </products> 
    </item> 
    <item> 
    <products> 
     <product>laptop</product> 
     <product>headphones</product> 
    </products> 
    </item> 
</items> 

Я хочу его к выходу, как

 
laptop 
charger 
headphones 

Я пытался использовать distinct-values(), но я предполагаю, что я делаю что-то неправильно , Может ли кто-нибудь сказать мне, как достичь этого, используя distinct-values()? Благодарю.

<xsl:template match="/">    
    <xsl:for-each select="//products/product/text()"> 
    <li> 
     <xsl:value-of select="distinct-values(.)"/> 
    </li>    
    </xsl:for-each> 
</xsl:template> 

но его дает мне такой вывод:

<li>laptop</li> 
<li>charger</li> 
<li>laptop></li> 
<li>headphones</li> 

Answer 1

XSLT 1.0 решение, которое использует key и функция generate-id(), чтобы получить различные значения:

<?xml version="1.0" encoding="UTF-8"?> 
    <xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/> 

<xsl:key name="product" match="/items/item/products/product/text()" use="." /> 

<xsl:template match="/"> 

    <xsl:for-each select="/items/item/products/product/text()[generate-id() 
             = generate-id(key('product',.)[1])]"> 
    <li> 
     <xsl:value-of select="."/> 
    </li> 
    </xsl:for-each> 

</xsl:template> 

</xsl:stylesheet> 

Answer 2

distinct-values(//product/text())

Answer 3

Вы не хотите "вывода (отличных стоимостей)", а «для-каждого (distinct- значения) ":

<xsl:template match="/">    
    <xsl:for-each select="distinct-values(/items/item/products/product/text())"> 
    <li> 
     <xsl:value-of select="."/> 
    </li> 
    </xsl:for-each> 
</xsl:template> 

Answer 4

Вот XSLT 1.0 решение, которое я использовал в прошлом, я думаю, что это более лаконичным (и чтения), чем при использовании функции generate-id().

<xsl:template match="/">   
    <ul> 
     <xsl:for-each select="//products/product[not(.=preceding::*)]"> 
     <li> 
      <xsl:value-of select="."/> 
     </li> 
     </xsl:for-each>    
    </ul> 
    </xsl:template> 

Возвращает:

<ul xmlns="http://www.w3.org/1999/xhtml"> 
    <li>laptop</li> 
    <li>charger</li> 
    <li>headphones</li> 
</ul> 

Answer 5

Я пришел к этой проблеме во время работы с XSL рендеринга Sitecore. Оба подхода, которые использовали key() и подход, который использовал предыдущую ось, выполнялись очень медленно. Я закончил использование метода, аналогичного key(), но для этого не требуется использовать key(). Он работает очень быстро.

<xsl:variable name="prods" select="items/item/products/product" /> 
<xsl:for-each select="$prods"> 
    <xsl:if test="generate-id() = generate-id($prods[. = current()][1])"> 
    <xsl:value-of select="." /> 
    <br /> 
    </xsl:if> 
</xsl:for-each>