Замена назначения строки с помощью операции PChar

Question

У меня есть загадочный результат, который я пытаюсь понять.

Я пытается улучшить скорость этого рутинного

function TStringRecord.GetWord: String; 
begin 
    // return the next word in Input 
    Result := ''; 

    while (PC^ <> #$00) and not PC^.IsLetter do begin 
    inc(FPC); 
    end; 

    while (PC^ <> #$00) and PC^.IsLetter do begin 
    Result := Result + PC^; 
    inc(FPC); 
    end; 
end; 

, заменив Result := Result + PC^ операцией указателей. Это моя попытка:

function TStringRecord.GetWord2: String; 
var 
    Len : Integer; 
    StartPC, 
    DestPC : PChar; 
begin 
    // return the next word in Input 
    Result := ''; 

    while (PC^ <> #$00) and not PC^.IsLetter do begin 
    inc(FPC); 
    end; 

    Len := Length(Input); 
    SetLength(Result, Len); 
    StartPC := PChar(Result); 
    DestPC := PChar(Result); 
    while (PC^ <> #$00) and PC^.IsLetter do begin 
    WStrPLCopy(DestPC, PC, 1); 
    inc(FPC); 
    inc(DestPC); 
    end; 
    SetLength(Result, DestPC - StartPC); 
end; 

По моей линии профилировщике WStrPLCopy(DestPC, PC, 1) занимает в 50 раз больше, чем Result := Result + PC^. Насколько я могу судить, это потому, что при входе в WStrPLCopy есть вызов _WStrFromPWChar, который, похоже, скопирует еще много символов , чем тот, который вам нужен. Как я могу избежать этого, или кто-то может предложить альтернативный метод на основе PChar?

Остальная часть моего кода ниже:

TStringRecord = record 
private 
    FPC: PChar; 
    FInput: String; 
    procedure SetInput(const Value: String); 
public 
    function NextWord : String; 
    function NextWord2 : String; 
    property Input : String read FInput write SetInput; 
    property PC : PChar read FPC; 
end; 

procedure TStringRecord.SetInput(const Value: String); 
begin 
    FInput := Value; 
    FPC := PChar(Input); 
end; 

Answer 1

Это, как я хотел бы написать это:

function TStringRecord.GetWord: String; 
var beg: PChar; 
begin 
    // return the next word in Input 
    while (FPC^ <> #0) and not FPC^.IsLetter do 
    inc(FPC); 
    beg := FPC; 
    while (FPC^ <> #0) and FPC^.IsLetter do 
    inc(FPC); 
    SetString(result, beg, FPC-beg); 
end; 

При этом, код очень читаемый, и у вас есть одно распределение памяти, и я думаю, вы не могли бы написать что-либо быстрее (но встраивая PC^.IsLetter, что является единственным вызовом внешней части кода).